Можно ли указать массив в качестве источника для Grid

Вопрос
Можно ли в качестве источника данных для Grid указать массив?

APPEND FROM ARRAY ...
***или
INSERT INTO ... FROM ARRAY ...

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Как выделить всю активную строку Grid

Вопрос
При перемещении по Grid выделяется только активная ячейка. Как выделить цветом все ячейки активной строки Grid ?

1. Необходимо создать дополнительное свойство формы ThisForm.nRecno. Можно сделать собственный класс Grid и создать этой свойство у собственно класса. И присвоить этому свойству числовое значение, например nRecno=1
   
   Новое свойство можно добавить через пункт меню Form (для класса Class), подпункт New Property или Edit Property/Method.
   
   
2. В событии Grid.Init пишем следующий код

IF RECNO(This.RecordSource)#0 
    THIS.SetAll("DynamicBackColor",;
        "IIF(RECNO(This.RecordSource)=ThisForm.nRecno,RGB(255,255,0),RGB(255,255,255))",;
        "COLUMN") 
ENDIF

Если свойство nRecno создано непосредственно в классе Grid, то, разумеется, следует вместо ThisForm.nRecno писать This.nRecno

3. В событии Grid.AfterRowColChange пишем следующий код

LPARAMETERS nColIndex
ThisForm.nRecno = RECNO(This.RecordSource) 
This.Refresh()
***Если свойство nRecno создано непосредственно в классе Grid, то, разумеется, следует вместо ThisForm.nRecno писать This.nRecno

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Почему настройки ячейки видны только в активной ячейке

Вопрос
Я сделал настройки ячейки Grid (объекта Text1 в столбце): формат, выравнивание, отображение NULL и т.п. Однако эти настройки действуют только на текущую (активную) ячейку Grid. Как мне распространить действие этих настроек на все ячейки того же столбца?

Я вставили в Grid вместо стандартного объекта Text1 какой-либо свой объект (например, ComboBox или свой TextBox). Однако мой объект виден только в текущей (активной) ячейке Grid. Как мне заставить отобразиться мой объект во всех ячейках того же столбца?

ThisForm.Grid1.Column1.Sparce = .F.

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Кто в данный момент работает с приложением

Вопрос:
Кто в данный момент работает с приложением

• SYS(0) – Идентификатор компьютера и логин пользователя при входе в Windows
• Логин пользователя при входе в Ваше приложение
• Дата и время последнего входа в Ваше приложение
• GetEnv("SessionName") – имя сессии, в которой запущено приложение.
  
  

  Замечание:
  Функция GetEnv() возвращает значение переменной созданной операционной системой. Полный список таких переменных и их значение можно посмотреть из режима командной строки Windows. Нажмите кнопку "Пуск" и выберите пункт меню "Выполнить". В появившемся окне введите в командной строке команду "cmd.exe" (разумеется, без кавычек) и нажмите кнопку "Ok" или "Enter". В открывшемся черном окне введите команду "set" и нажмите "Enter".

  
  Теперь, при входе в Ваше приложение, первым делом открываете эту служебную таблицу и ищете запись с полным набором идентификаторов, однозначно определяющих данный процесс. Если такой записи нет, то создаете ее.
  
  После того, как запись найдена (или создана) предпринимаете попытку ее заблокировать. Если это не удалось, то значит приложение уже запущено. Если требуется, тем не менее, разрешить повторный запуск приложения, то создаете еще одну строку с тем же набором реквизитов и блокируете эту новую строку.
  
  Теперь, когда Вам потребуется узнать, кто же в данный момент работает с приложением, Вы просто выполняете сканирование этой таблицы на предмет поиска тех записей, которые также заблокированы. Прочитав их реквизиты, Вы получите информацию о том, кто в данный момент работает с приложением.
  
  В коде это будет выглядеть примерно так.
  
  Служебная таблица имеет примерно такую структуру

CREATE TABLE curProc (CurProcID I AutoInc, SYS0 C(128), LastTime T)

Здесь CurProcID - это код записи. В данном случае использовано тип данных Integer-Autoincrement, который был введен только в версии Visual FoxPro 8.0. Для младших версий FoxPro можно формировать код записи при помощи специальной функции NewId() или любым удобным для Вас способом.

Идентификатором процесса выступает сетевое имя компьютера SYS(0)

Тогда собственно код функции при открытии приложения будет таким

 * Запоминаю текущую сессию данных  
  LOCAL lnSessionCurrent  
  lnSessionCurrent = SET("DataSession")  
    
 * Проверяю факт создания частной сессии данных  
  IF Type("m.goSessionUsers") = "U"  
      PUBLIC goSessionUsers  
      goSessionUsers = CreateObject("Session")  
     * Перехожу в созданную сессию данных  
      Set DataSession To goSessionUsers.DataSessionId  
     * Выполняю настройки в этой сессии  
      SET REPROCESS TO 3      
      SET TALK OFF  
      SET MULTILOCK ON  
  Else  
     * Перехожу в частную сессию данных  
      Set DataSession To goSessionUsers.DataSessionId  
  EndIf  
    
 * Собственно поиск и блокировка записи  
  IF USED("curProc")=.F.  
      USE curProc IN 0 SHARED    
  ENDIF  
  SELECT curProc    
  LOCATE FOR SYS0 = SYS(0)    
  IF FOUND()=.F.    
      INSERT INTO curProc (SYS0) VALUES (SYS(0))    
  ENDIF    
    
  IF RLOCK()=.F.    
     * Запись блокирована другим процессом    
     * Т.е. предпринята попытка повторного запуска приложения    
  ELSE    
     * Записываю время входа    
      REPLACE LastTime WITH DateTime()    
  ENDIF    
    
 * Возвращаюсь в исходную сессию данных  
  Set DataSession To m. lnSessionCurrent  
    

Снимать блокировку записи не надо до окончания работы приложения. В случае аварийного завершения приложения (сбой питания) снятие блокировки произойдет автоматически.

Если при закрытии приложения удалять (или очищать) созданную запись, то по факту наличия не заблокированной записи можно сделать вывод о том, что приложение было закрыто аварийно. И определить кем именно.

Запись времени нужна для того, чтобы не накапливался мусор. Например, уже нет компьютера со значением SYS(0), но запись с таким значением все еще существует. Вот по времени последнего обращения можно оценить: оставлять такую запись или уже пора удалять.

Теперь, собственно код, определяющий, кто же в данный момент работает с Вашим приложением.

 * Запоминаю текущую сессию данных  
  LOCAL lnSessionCurrent  
  lnSessionCurrent = SET("DataSession")  
    
 * Проверяю факт создания частной сессии данных  
  IF Type("m.goSessionUsers") = "U"  
     * Это ошибка.   
     * К моменту вызова данной функции частная сессия должна быть уже создана  
     * Поэтому прерываю процесс с сообщением об ошибке  
      MessageBox("Нет сессии данных служебной таблицы")  
      Return  
  Else  
     * Перехожу в частную сессию данных  
      Set DataSession To goSessionUsers.DataSessionId  
  EndIf  
    
 * Большинство настроек уже все выполнены при создании частной сессии данных   
 * в момент запуска приложения. Однако одну настройку следует установить  
 * не забыв сохранить исходное значение  
  LOCAL lnReporcess  
  lnReporcess = SET("REPROCESS")  
  SET REPROCESS TO 0 SECONDS    && Спасибо Вадиму (piva) за подсказку ключевого слова SECONDS      
    
 * Создаю временную таблицу со структурой, дублирующей структуру служебной таблицы    
 * В эту временную таблицу будет записан результат поиска   
 * Опция READWRITE была введена только в версии Visual FoxPro 7  
 * Чтобы сделать курсор редактируемым в младших версиях FoxPro  
 * его придется переоткрыть повторно в другой рабочей области.  
 * Замечу также, что при таком запросе поле типа Integer-Autoincrement исходной таблицы  
 * конвертируется в поле с обычным типом Integer, что, в данном случае, как раз и требуется   
  USE IN SELECT('curCon')    
  SELECT * FROM curProc INTO CURSOR curCon NOFILTER READWRITE WHERE .F.    
        
 * Собственно поиск записей, заблокированных другими процессами    
  LOCAL laFields(1)    
  select curProc     
  SET ORDER TO 0    
  SCAN    
      IF IsRLocked() = .T. OR RLOCK() = .F.    
         * Эта запись содержит информацию о пользователе,     
         * использующем данное приложение в настоящий момент    
         * Копирую ее в итоговый курсор  
          SCATTER TO laFields    
          INSERT INTO curCon FROM ARRAY laFields    
      ELSE    
         * Поскольку удалось установить блокировку, то данная запись никем не используется  
         * Снимаю с нее блокировку и перехожу к следующей записи  
          UNLOCK RECORD Recno()    
      ENDIF    
  ENDSCAN    
    
 * Возвращаюсь к записи заблокированной при входе в текущую копию приложения  
  LOCATE FOR IsRLocked() = .T.    
    
 * Восстанавливаю исходную настройку текущей сессии  
  SET REPROCESS TO m.lnReporcess     
    
 * Отображение результата поиска    
  select curCon    
  GO TOP    
  BROWSE NOWAIT  
    
 * Возвращаюсь в исходную сессию данных  
  Set DataSession To m.lnSessionCurrent  
    

Следует заметить, что курсор curCon существует только в той сессии данных, где он и был создан. Поэтому, вернувшись в исходную сессию данных, Вы уже не увидите результат поиска. Если Вы хотите отображать результат поиска в другой сессии данных, то либо следует использовать постоянную таблицу (это не очень хорошее решение), либо озаботится копированием информации из курсора в другую сессию данных. Это можно сделать, например, через массив.

  LOCAL laStructure(1), laContent(1)  
    
  Select curCon    
 * Копирую структуру курсора в массив  
  =AFields(laStructure)  
 * Копирую содержимое курсора в массив  
  COPY TO ARRAY laContent  
 * Возвращаюсь в исходную сессию данных  
  Set DataSession To m.lnSessionCurrent  
 * Создаю новый курсор  
  CREATE CURSOR curCon FROM ARRAY laStructure  
 * Наполняю его данными из массива  
  APPEND FROM ARRAY laContent  

У копирования содержимого курсора через массив есть ограничения. Кроме того, есть и другие способы копирования, но это выходит за рамки данной статьи.

Кроме факта проверки кто в данный момент работает с Вашим приложением служебную таблицу можно использовать как способ ограничения количества одновременно работающих пользователей. Просто запретите создавать в этой таблице новые записи. Выделите, например, только 100 записей. Это и будет означать не более 100 одновременных подключений к Вашему приложению.

Смотрите также

Как предотвратить повторный запуск приложения

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Как предотвратить повторный запуск приложения

Вопрос:
Как предотвратить повторный запуск приложения?

• Запуск одного и того же приложения на одном компьютере вне зависимости от логина пользователя
• Запуск одного и того же приложения на одном компьютере из одной сессии в терминальном режиме
• Запуск одного и того же приложения с разных компьютеров с логином одного пользователя
• Работа с базой данных из разных приложений, но с логином одного пользователя
  
  И это далеко не полный перечень самых разных ситуаций, которые могут подразумеваться под термином "повторный запуск приложения".
  
  Собственно, вопрос сводится к набору признаков, по которому Вы хотите идентифицировать приложение. Причем эти признаки должны быть такими, которые однозначно определяются в момент открытия приложения и не могут быть изменены в процессе работы приложения.
  
  Именно поэтому, наиболее распространенный способ определения приложения по его заголовку не может служить таким уникальным идентификатором. По крайней мере, сам по себе. Без каких-либо дополнительных признаков. Просто потому, что заголовок окна приложения легко может быть изменен в процессе работы приложения или же один и тот же заголовок могут иметь разные приложения. Разные в том смысле, который Вы вкладываете в это понятие.
  
  Уникальными идентификаторами могут являться:
  
  
• SYS(0) – Идентификатор компьютера и логин пользователя при входе в Windows
• Логин пользователя при входе в Ваше приложение
• Дата и время последнего входа в Ваше приложение
• GetEnv("SessionName") – имя сессии, в которой запущено приложение. Имеет смысл при работе в терминальном режиме, поскольку значение, возвращаемое функцией SYS(0) будет одинаковым, но имя сессии - разным.
  
  Вам могут понадобиться и другие идентификаторы, формируемые либо внутри Вашего приложения, либо самой операционной системой для того, чтобы однозначно определить уникальный экземпляр приложения. Какие именно – решайте сами исходя из Вашей задачи.
  
  

  Замечание
  Функция GetEnv() возвращает значение переменной созданной операционной системой. Полный список таких переменных и их значение можно посмотреть из режима командной строки Windows. Нажмите кнопку "Пуск" и выберите пункт меню "Выполнить". В появившемся окне введите в командной строке команду "cmd.exe" (разумеется, без кавычек) и нажмите кнопку "Ok" или "Enter". В открывшемся черном окне введите команду "set" и нажмите "Enter".

  
  Теперь, когда Вы определились с набором признаков, идентифицирующих Ваше приложение, встает следующий вопрос: как и где, хранить этот набор, чтобы он был доступен из другого приложения?
  
  Это "хранилище" реквизитов должно удовлетворять следующим требованиям:
  
  1. Формироваться в момент открытия приложения
  2. Быть недоступным для изменения из другого приложения в процессе работы приложения, его создавшего. Однако должно быть доступным на чтение.
  3. Очищаться при закрытии приложения. Даже если закрытие приложения произошло в аварийном режиме (сбой питания)
  
  Ну, очевидно, идеальным вариантом такого хранилища является само приложение. Точнее, набор переменных памяти, которые создает само приложение.
  
  Однако использовать напрямую приложение затруднительно. По ряду причин. Например, при таком подходе необходимо будет просканировать вообще все открытые приложения. Ведь заранее неизвестно, какое именно приложение нам нужно найти. Есть и другие причины.
  
  Но, тем не менее, существует довольно простое решение данной проблемы. Это использование так называемых, объектов-семафоров. Эти объекты создаются при помощи специальных API-функций и их можно "увидеть" извне приложения. Т.е. любое другое приложение может сразу определить, существует ли искомый объект или нет.
  
  Поскольку в данном случае необходимо определить существование одного и только одного экземпляра приложения, то лучше всего использовать объект Mutex. Свое название он получил от выражения "mutually exclusive", что означает "взаимно исключающий".
  
  

  Замечание
  Если у Вас стоит задача допустить существование фиксированного количества одновременно запущенных экземпляров приложений, то можно использовать объект Semaphore. Но организационно это значительно сложнее.

  
  Полное описание способов использования объекта Mutex смотрите в библиотеке MSDN на сайте Microsoft. В данном случае будет описан один единственный способ, реализующий необходимую функциональность.
  
  Прежде, чем использовать объект Mutex в приложении, необходимо объявить API-функцию для его создания с именем CreateMutex.

  Declare Integer CreateMutex In Win32API ;  
      Integer lpMutexAttributes, ;  
      Integer bInitialOwner, ;  
      String lpName  
    

lpMutexAttributes – атрибуты защиты. В данном случае не используются, поэтому значение этого параметра устанавливается в 0.

bInitialOwner – начальное состояние объекта в момент инициализации. Значение 1 означает, что приложение создавшее объект становится владельцем этого объекта. Значение 0 означает, что приложение только создает объект, но не владеет им. В данном случае всегда следует использовать значение 1.

lpName – имя объекта. Не должно содержать символа "\" и общая длина не должна превышать 260 символов (MAX_PATH). Регистр букв (большие или маленькие) имеет значение. Т.е для объекта Mutex большие и маленькие буквы – это разные буквы.

Именно имя и будет являться тем уникальным идентификатором, по значению которого и будет определяться факт существования приложения с определенными значениями реквизитов. Само имя – это символьная строка "сложенная" из значений необходимых идентификаторов. Исключая символ "\" и длиной не более 260 символов.

Замечание

В терминальном режиме все объекты ядра (kernel), в том числе и объект mutex, работают в так называемом "пространстве имен". В терминах FoxPro можно сказать, что они имеют определенную "область видимости". По умолчанию, они имеют "область видимости" Session. Это значит, что они "видны" только в той терминальной сессии, в которой и были созданы. Другая сессия (другой пользователь) уже их не видит.

Чтобы созданный объект Mutex был виден из других сессий ему надо задать пространство имен Global. Это делается добавлением префикса "Global\" к сформированному имени. Т.е. имя будет выглядеть так:

lpName = "Global\Имя_объекта"

Подробнее о пространстве имен объектов ядра в терминальном режиме читайте здесь Kernel Object Namespaces

Функция CreateMutex возвращает так называемый, "хендл" или идентификатор объекта. Целое число. Однако данная функция может, как создать объект, так и вернуть ссылку на уже существующий объект созданный ранее другим приложением.

Чтобы определить, был ли объект Mutex действительно создан или Вы получили ссылку на ранее созданный объект, следует использовать другую API-функцию с именем GetLastError.

Если эта функция вернет значение 183 (ERROR_ALREADY_EXISTS), то это и будет означать тот факт, что объект Mutex с тем же именем уже был ранее создан. Т.е. было ранее запущено приложение с теми же реквизитами.

В принципе, объект Mutex и все ссылки на него автоматически удаляются при закрытии приложения. Поэтому можно и не давать специальные команды по удалению этого объекта из памяти. Но уборка за собой является хорошим тоном в программировании. Поэтому, лучше все-таки выполнить удаление объекта Mutex при закрытии приложения.

Простейший код использования объекта Mutex для проверки факта существования ранее запущенного приложения будет выглядеть примерно так.

 * Формируем идентификатор данного приложения  
  LOCAL lcApplicationName  
  lcApplicationName = GetEnv("SessionName") + "#"+ SYS(0)  
    
 * Формируем ссылку на объект Mutex  
  Declare Integer CreateMutex In Win32API ;  
      Integer lpMutexAttributes, ;  
      Integer bInitialOwner, ;  
      String lpName  
    
  PUBLIC gnMutex  
  gnMutex = CreateMutex(0,1,m.lcApplicationName)  
    
 * Проверяем факт существования объекта Mutex с тем же именем  
  #DEFINE ERROR_ALREADY_EXISTS 183  
  Declare integer GetLastError In Win32API  
    
  If GetLastError() = ERROR_ALREADY_EXISTS  
     * Приложение уже запущено  
     * Надо вывести ранее запущенное приложение на передний план  
     * или сообщить об этом факте пользователю  
     * и закрыть текущее приложение  
      Do CloseMutex with .T.  
      Return  
  EndIf  
    
 * Если объект Mutex был именно создан, то нет ранее запущенного приложения   
 * и можно запускать текущее приложение  
    
  ...  
  READ EVENTS  
    
 * По окончании работы приложения надо удалить объект Mutex, хотя это и не обязательно  
  Do CloseMutex with .F.  
  Return  
    
 * Процедура удаления объекта Mutex  
  Procedure CloseMutex  
  LParameters IsExists    && существует ли другое приложение  
    
 * Если другое приложение существует, то удалять объект Mutex не надо  
 * Удаление выполняется только если объект был создан именно в этом приложении  
  If IsExists = .f.  
     * Удаление объекта Mutex  
      Declare integer ReleaseMutex IN Win32API Integer hMutex  
      ReleaseMutex(m.gnMutex)  
  EndIf  
    
 * Закрытие уже не нужного хендла объекта Mutex  
  Declare integer CloseHandle IN Kernel32 Integer hObject  
  CloseHandle(m.gnMutex)  
    
  EndProc  

Однако, несмотря на все достоинства использования объекта Mutex, его использование имеет и недостатки. Дело в том, что данный объект существует только и исключительно в памяти того компьютера, в котором он был создан.

В большинстве случаев это не является проблемой, поскольку требуется проконтролировать факт повторного запуска приложения на одном и том же компьютере. Но если Вам надо контролировать факт запуска приложения, например, одного и того же пользователя, но с разных компьютеров, то использование объекта Mutex не решает проблему.

Возвращаясь к требованиям, предъявляемым к "хранилищу" реквизитов приложения по которым определяется факт запуска приложения, дополняем его еще одним требованием.

4. Оно должно быть доступным для чтения с разных компьютеров.

В принципе, можно реализовать и это требование при помощи объекта Mutex, если создавать его всегда только на том компьютере, где хранятся общие данные приложения. Т.е. создавать этот объект на сервере. Это можно реализовать, создав специальную библиотеку Com+. Но описание данной технологии выходит за рамки данной стать. Кроме того, есть другой способ.

Дело в том, что в самой среде FoxPro есть механизм взаимодействия нескольких пользователей одного приложения. Это блокировки. Ведь запись, заблокированную одним пользователем невозможно изменить другим пользователем, хотя можно прочитать из нее информацию.

Это значит, что если создать специальную таблицу, включенную в базу данных, записи которой будут содержать информацию о факте запуска приложения, то, наложив блокировку на соответствующую запись, можно дать знать другим экземплярам приложения кто уже работает с приложением.

Чтобы операции с этой служебной таблицей не мешали основной работе приложения, лучше открывать ее в отдельной сессии данных. Это можно сделать, например, используя объект Session, введенный в Visual FoxPro 6.0 Service Pack 3. Для младших версий FoxPro придется очень аккуратно следить за установкой и снятием блокировок с таблиц. Т.е. за командами UNLOCK, RLOCK(), LOCK(), SET MULTILOCKS. Хотя, можно использовать невидимую форму.

Итак, в базе данных создается еще одна таблица. Это обычная таблица, принадлежащая базе данных. Т.е. таблица, лежащая на сервере, а не на локальном компьютере пользователя.

Список полей этой таблицы является набором идентификаторов, по которым в Вашей задаче надо отделять процессы друг от друга. Это может быть, например:

SYS(0) – Идентификатор компьютера и логин пользователя при входе в Windows
Логин пользователя при входе в Ваше приложение
Дата и время последнего входа в Ваше приложение
GetEnv("SessionName") – имя сессии, в которой запущено приложение.

Теперь, при входе в Ваше приложение, первым делом открываете эту служебную таблицу и ищете запись с полным набором идентификаторов, однозначно определяющих данный процесс. Если такой записи нет, то создаете ее.

После того, как запись найдена (или создана) предпринимаете попытку ее заблокировать. Если это не удалось, то значит приложение уже запущено.

В коде это будет выглядеть примерно так.

Служебная таблица имеет примерно такую структуру

CREATE TABLE curProc (CurProcID I AutoInc, SYS0 C(128), LastTime T)

Здесь CurProcID - это код записи. В данном случае использовано тип данных Integer-Autoincrement, который был введен только в версии Visual FoxPro 8.0. Для младших версий FoxPro можно формировать код записи при помощи специальной функции NewId() или любым удобным для Вас способом.

Идентификатором процесса выступает сетевое имя компьютера SYS(0)

Тогда собственно код функции будет таким

 * Запоминаю текущую сессию данных  
  LOCAL lnSessionCurrent  
  lnSessionCurrent = SET("DataSession")  
    
 * Проверяю факт создания частной сессии данных  
  IF Type("m.goSessionUsers") = "U"  
      PUBLIC goSessionUsers  
      goSessionUsers = CreateObject("Session")  
     * Перехожу в созданную сессию данных  
      Set DataSession To goSessionUsers.DataSessionId  
     * Выполняю настройки в этой сессии  
      SET REPROCESS TO 3  
      SET TALK OFF  
      SET MULTILOCKS ON  
  Else  
     * Перехожу в частную сессию данных  
      Set DataSession To goSessionUsers.DataSessionId  
  EndIf  
    
 * Собственно поиск и блокировка записи  
  IF USED("curProc") = .F.  
      USE curProc IN 0 SHARED   
  ENDIF   
  SELECT curProc    
  LOCATE FOR SYS0 = SYS(0)    
  IF FOUND()=.F.    
      INSERT INTO curProc (SYS0) VALUES (SYS(0))    
  ENDIF    
    
  IF RLOCK()=.F.    
     * Запись блокирована другим процессом    
     * Т.е. предпринята попытка повторного запуска приложения    
  ELSE    
     * Записываю время входа    
      REPLACE LastTime WITH DateTime()    
  ENDIF    
        
 * Возвращаюсь в исходную сессию данных  
  Set DataSession To m.lnSessionCurrent  

Снимать блокировку записи не надо до окончания работы приложения. В случае аварийного завершения приложения (сбой питания) снятие блокировки произойдет автоматически.

Если при закрытии приложения удалять (или очищать) созданную запись, то по факту наличия не заблокированной записи можно сделать вывод о том, что приложение было закрыто аварийно. И определить кем именно.

Запись времени нужна для того, чтобы не накапливался мусор. Например, уже нет компьютера со значением SYS(0), но запись с таким значением все еще существует. Вот по времени последнего обращения можно оценить: оставлять такую запись или уже пора удалять.

Также эту таблицу можно использовать для получения сведений о том, кто в данный момент работает с приложением

Смотрите также

Как вывести приложение на передний план
Заметки на сайте Юрия Шутенко
Kernel Object Namespaces

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Пропадают настройки Grid, события столбцов, заголовков, ячеек

Проблема
В дизайнере формы были сделаны настройки Grid, написана собственная обработка события Header.Click() или Column.Text1.Click(). Однако при выполнении программы все эти настройки пропадают.

Причина
Это происходит после переоткрытия источника данных для Grid. Того, что указано в качестве Grid.RecordSource. Т.е. эта таблица была закрыта и открыта заново. Как правило, это является следствием использования команды PACK, но могут быть и более сложные варианты.

Решение
Прежде всего, следует заметить, что использование команды PACK в активной форме - это порочная практика. Физическое удаление записей следует вынести в отдельную служебную процедуру, периодически запускаемую администратором.

Тем не менее, если подобная задача все-таки необходима, то перед переоткрытием (или заменой) источника данных для Grid его следует сбросить.

* Сброс источника данных Grid
ThisForm.Grid1.RecordSource = ""
* Выполнение переоткрытия таблицы, модификация данных, выбор другой таблицы
...
* Восстановление источника данных Grid
ThisForm.Grid1.RecordSource = "Table"
ThisForm.Grid1.Column1.ControlSource = "Table.Field1"
ThisForm.Grid1.Column2.ControlSource = "Table.Field2"
ThisForm.Grid1.Column3.ControlSource = "Table.Field3"

В случае необходимости, можно автоматизировать процесс сохранения и восстановления настроек источника данных столбцов Grid. Подробнее об этом способе читайте в статье

VFP грид, часть I

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Как в дизайнере вставить объект в столбец Grid

Вопрос

Как в дизайнере формы я могу вставить нужный мне объект (ComboBox, CheckBox, Image, CommandButton, свой класс и т.п.) в столбец Grid?

Ответ

• Добавляете на форму объект Grid
• Устанавливаете у него свойство ColumnCount больше нуля
• Правой клавишей мыши щелкаете на Grid и выбираете пункт Edit. В старших версиях FoxPro в этот режим можно перейти, нажав и удерживая клавишу Ctrl щелкнув по Grid левой клавишей мыши
• В ToolBar с именем Form Controls щелкните левой клавишей мыши по нужному объекту
• Левой клавишей мыши щелкаете на нужном столбце в любом месте под заголовком

Все, нужный объект вставлен. Убедится в это можно в окне Poperties. В раскрывающемся списке в соответствующем столбце Grid кроме объекта Text1 появиться и имя вставленного Вами объекта с добавлением окончания 1.

Чтобы именно вставленный объект отображался в столбце, необходимо убедится, что свойство CurrentControl этого столбца содержит имя вставленного объекта.

А чтобы вставленный Вами объект отображался не только в текущей строке Grid, но и во всех остальных строках необходимо для того же столбца сделать дополнительную настройку

Sparse = .F.

Можно также использовать другой метод вставки

• Добавляете на форму объект Grid
• Устанавливаете у него свойство ColumnCount больше нуля
• Добавьте экземпляр любого нужного Вам класса, который Вы хотите вставить в столбец Grid непосредственно на форму вне Grid
• Выделите добавленный объект (щелкнув по нему левой клавишей мыши) и скопируйте его в буфер обмена (комбинация клавиш Ctrl+C или пункт системного меню Edit, подпункт Copy)
• Правой клавишей мыши щелкаете на Grid и выбираете пункт Edit. В старших версиях FoxPro в этот режим можно перейти, нажав и удерживая клавишу Ctrl щелкнув по Grid левой клавишей мыши
• Левой клавишей мыши щелкаете на нужном столбце в любом месте под заголовком
• Сделайте вставку из буфера обмена (комбинация клавиш Ctrl+V или пункт системного меню Edit, подпункт Paste)

Можно удалить уже не нужный объект Text1 из столбца Grid следующим образом:

• В окне Properties в раскрывающемся списке выберите объект, который хотите удалить
• Один раз щелкните левой клавишей мыши по любому месту формы. Лучше щелкнуть по заголовку формы, хотя это не принципиально.
• Нажмите клавишу Delete на клавиатуре

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

В деталях отчета частично “съедается” информация

Проблема

Случалось ли кому сталкиваться с такой историей:
в деталях отчета частично "съедается" информация. Например, типовой отчет типа "счет", наименование товара может может занять от 1 до 4-х строк. До 2-х включительно все хорошо. Но если 4-ре строки, то начинается мистика:
в документе, где много наименований (товаров), часть информации просто на полуслове теряется. Те же наименования в том же отчете, но в документе с 2...3 товарами, отображаются корректно.

Ответ

Для «обрезанного» поля надо задать длину либо cast(... as c(254)) либо padr(..., 254) либо Memo

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Как определить в каком VFP сделано приложение

А как определить в каком VFP сделанно приложение либо при установки последних библиотек это не имеет значения ?

Открываете файл EXE как текстовый файл (можно в блокноте Notepad) и где-то в самом начале этого файла должна быть строка "VisualFoxProRuntime". Сразу за ней после точки будет стоять цифра, обозначающая номер версии FoxPro в которой был скомпилирован данный EXE. Для VFP9 это будет строка "VisualFoxProRuntime.9"

Однако проблема в том, что таким образом можно узнать только собственно версию без определения ServicePack. А при запуске приложения нужны RunTime библиотеки с точностью именно до ServicePack. Например, если приложение было скомпилировано в VFP9SP1, то и RunTime библиотеки должны быть от VFP9SP1. Если будут установлены библиотеки VFP9SP2, то будет аналогичное сообщение об ошибке.

Вам придется либо поискать библиотеки и просто их скопировать в папку с EXE, либо действовать методом "научного тыка".

1. Установить "голый" VFP9. Проверить работоспособность
2. Если не работает, накатить SP1. Проверить
3. Если не работает, деинсталировать VFP9, снова установить и накатить SP2.

Накатить SP2 поверх SP1 - не получится. В рекомендациях по установке советуют деинсталировать VFP9SP1, а потом устанавливать отдельно VFP9 с последующей установкой SP2

Да, нужна еще сишная библиотека msvcr71.dll. Эту библиотеку надо регистрировать через regsvr32.

Для старта приложения необходимый "минимум": msvcr71.dll, vfp9r.dll, vfp9renu.dll

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Почему в готовом EXE не работает копирование по Ctrl+C, Ctrl+V

Проблема

На этапе разработки приложения работало копирование через буфер обмена (горячие клавиши Ctrl+C, Ctrl+V), но в готовом файле EXE эти комбинации клавиш не работают. Как можно исправить эту ситуацию?

Причина и решение проблемы приведены в разделе посвященном меню

Почему в готовом EXE не работает копированиепо Ctrl+C, Ctrl+V

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Как прикрепить к файлу EXE свою иконку

Вопрос
Я создал EXE-файл. Однако в проводнике Windows и на рабочем столе связанная с моим файлом иконка - это либо лисья мордочка, либо иконка флага Windows. Как мне прикрепить к моему файлу EXE нужную мне иконку.

Ответ
Сам факт прикрепления иконки к EXE-файлу можно организовать двумя способами:

1. Воспользоваться пунктом основного меню "Project" - "Project info" - закладка "Project" - поставить "птичку" в пункте "Attach icon" и выбрать нужную иконку
2. Программно, в главном (стартовом) файле дать команду

   _SCREEN.icon = "MyIcon.ico"

Эти два способа не взаимозаменяемые, а взаимодополняющие.

Добавление иконки в свойствах проекта отвечает за отображение иконки в тех случаях, когда собственно программа не запускается. В проводнике Windows или ярлык на рабочем столе.

Указание иконки для объекта _SCREEN определяет изображение в левом верхнем углу основного окна приложения, если приложение использует окно _SCREEN в качестве основного окна приложения.

Замечание

Если Вы создаете приложение на базе форм со свойством Form.ShowWindow = 2 - As Top-Level, то необходимо будет прикрепить соответствующую иконку к свойству самой формы

Form.icon = "MyIcon.ico"

Поскольку в этом случае нет основного окна FoxPro с именем _SCREEN. Соответственно, не будут отображаться и иконки прикрепленные к этому окну. Вместо него отображается Ваша форма со свойством As Top-Level

Однако каким бы способом Вы ни воспользовались, необходимая иконка должна быть доступна к моменту ее использования. Лучше включить ее внутрь проекта. Т.е. добавить в сам проект на закладку "Other" в группу "Other Files"

Ассоциируемая иконка должна обладать следующими свойствами:

• Иконка - это именно иконка. Т.е. файл с расширением "ico"
• Иконка (сам файл ico) должна содержать в себе две картинки - 16х16 пикселей и 32х32 пикселей
• Иконка должна иметь столько цветов, сколько поддерживает как текущая версия FoxPro, так и операционная система Windows.
• Файл EXE должен быть собран (создан) в той версии операционной системы Windows, которая указана в системных требованиях к Вашей версии FoxPro.

  В принципе, FoxPro поддерживает отображение иконок 3 размеров: 16х16, 32х32 и 48х48. Однако размер 48х48 практически нигде не используется. Впрочем, можете также включить иконку размера 48х48 в свой файл ico. Хотя практического смысла это не имеет.

  Также FoxPro поддерживает изображение иконок в 4 наборах цветов: 16 Color, 256 Color, True Color (16 bit), True Color (24 bit). Для своей иконки лучше использовать минимальный цветовой набор - 16 Color или 256 Color. Мало ли, какие установки будут сделаны на машине клиента. А 256 Color поддерживают практически все видео карты.

  Если в системных требованиях для Вашей версии FoxPro указано, что разработка приложения должна осуществляться в версии Windows 2000 или Windows XP, то не стоит пытаться собрать готовый файл EXE в младшей версии. Например, в Windows 98. Вполне возможно, что Вы получите работоспособный файл EXE, но, скорее всего, "в комплекте" Вы получите массу глюков. Например, не будет отображаться присоединенная иконка.

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Часть букв при вводе заменяются латинскими

Проблема
При отладке приложения все в порядке, а в готовом файле EXE в процессе ввода часть русских букв автоматически заменяются латинскими буквами

Причина
Причина в несовпадении кодовых страниц.

По умолчанию, если кодовая страница не указана явно, то до версии Visual FoxPro 6 включительно, и на этапе отладки приложения и в готовом файле EXE кодовая страница устанавливается такая же, как и кодовая страница Windows.

Однако, начиная с версии Visual FoxPro 7, на этапе отладки кодовая страница по-прежнему устанавливается как кодовая страница Windows, но в готовом файле EXE будет установлена кодовая страница 1252 (Windows ANSI)

Решение

Необходимо явно указать в какой кодовой странице следует работать. Это можно сделать одним единственным способом.
Надо создать файл конфигурации CONFIG.FPW. Это обычный текстовый файл. И написать в нем строчку

CODEPAGE=1251

Файл конфигурации можно подключить несколькими способами. Наиболее распространенными являются три варианта.

1. Включить файл конфигурации внутрь файла EXE.

   Для этого добавьте файл конфигурации в Ваш проект на закладке "Other" в раздел "Text Files". И убедитесь, что слева от имени файла нет значка перечеркнутого кружка.

   Все. Теперь файл конфигурации станет частью готового файла EXE и поставлять его клиенту как отдельный файл нет необходимости. Однако следует понимать, что такой файл невозможно будет изменить у клиента.

2. Положить файл конфигурации рядом с файлом EXE в ту же директорию

   По умолчанию, в момент запуска файла EXE, если файл конфигурации не включен внутрь файла EXE, то файл конфигурации будет подхвачен из той же директории, в которой находится файл EXE

3. Использовать специальный ключ, для указания пути доступа к файлу конфигурации

   Для явного указания пути доступа к файлу конфигурации можно использовать специальный именованный параметр (ключ). Примерно в таком синтаксисе

    

   MyProg.EXE -C"C:\MyDir\Config.fpw"

   Подробнее о передаче параметров файл EXE читайте в статье:

   Главный (стартовый) файл. Передача параметров в EXE

Замечание

Для версий до Visual FoxPro 5 включительно, следует также поставлять клиенту файл

FOXPRO.INT

Не надо путать его с ini-файлом, расширение от слова "international". Этот файл поставлялся вместе с FoxPro в его корневой директории. Его необходимо класть рядом с файлом EXE на машине клиента. Включать его внутрь файла EXE нельзя. Начиная с версии VFP6, надобность в нем отпала. Он уже не нужен.

Дополнительную информацию о возможных ошибках связанных с кодовыми страницами можете почитать здесь

Неверное отображение отдельных символов или несовпадение кодовых страниц
Проблема CODEPAGE у VFPxT.DLL

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Не запускается файл помощи в CHM-формате

Проблема
На машине клиента не запускается HELP, написанный в CHM-формате.

Причина
Приложение, написанное на FoxPro для работы с файлами в CHM-формате использует как ряд системных библиотек операционной системы, так и специфические дополнительные библиотеки, для организации вызова справки именно из приложений FoxPro.

Соответственно, могут быть две причны:

При установке операционной системы Windows не были установлены библиотеки для работы с файлами в CHM-формате
При переносе приложения на машину клиента не были установлены дополнительные библиотеки для работы с файлами в CHM-формате

Решение

Способ решения зависит от причины.

При установке операционной системы Windows не были установлены библиотеки для работы с файлами в CHM-формате

Для коректной работы CHM-файлов непосредственно в операционной среде Windows нужны следующие файлы

HHCTRL.OCX - элемент управления ActiveX HTML help (требует регистрации)
ITSS.DLL - Модуль DLL для компилированного HTML (требует регистрации)
ITIRCL.DLL - Модуль DLL для выполнения операций текстового поиска (требует регистрации)
HH.EXE - Программа просмотра HTML-документа

Как правило, файлы OCX и DLL кладут в папку C:\Windows\System32, а файл HH.EXE непосредственно в папку C:\Windows

Обычно никакой специальной установки для этих файлов не требуется. Они и так уже установлены в Windows. Но если созданный Вами файл CHM не открывается в самой операционной среде Windows (например, из проводника), то это означает, что проблема связана именно с этими файлами.

Все эти четыре файла можно установить специальной программой HHUPD.EXE, поставляемой вместе с FoxPro в директории программы HTML Help Workshop. Или скачать ее с сайта Microsoft. Т.е. запуск программы HHUPD.EXE на машине клиента должен привести к установке этих четырех системных файлов.

Однако программа HHUPD.EXE поможет только в том случае, если на машине клиента либо вообще нет этих файлов, либо они имеет более старую версию.

Если же эти файлы уже существуют и тем не менее файлы CHM не запускаются из среды Windows, то Вам необходимо будет перенести эти файлы в ручную с той машины, где файлы CHM нормально запускаются и зарегистрировать их вручную при помощи программы Regsvr32.exe примерно так

regsvr32.exe C:\Windows\System32\HHCTRL.OCX

Следует только помнить, что поскольку речь идет об ActiveX-компонентах их регистрация должна производится в сенасе работы с правами администратора. Это может быть еще одной причиной не работающих файлов справки. Сами файлы OCX были скопированы, но зарегистрировать их не удалось, поскольку установка производилась в сеансе работы не с правами администратора.

При переносе приложения на машину клиента не были установлены дополнительные библиотеки для работы с файлами в CHM-формате

Для работы CHM-файлов в среде FoxPro требуются следующие файлы

Visual FoxPro 6 FOXHHELPPS.DLL 
FOXHHELP.EXE
Visual FoxPro 7 FOXHHELPPS7.DLL 
FOXHHELP7.EXE
Visual FoxPro 8 FOXHHELPPS8.DLL 
FOXHHELP8.EXE
Visual FoxPro 9 FOXHHELPPS9.DLL 
FOXHHELP9.EXE
При этом регистрация имеет вид

regsvr32.exe FOXHHELPPS.DLL 
FOXHHELP.EXE /regserver

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Не могу изменить содержимое рабочих таблиц

ПроблемаПри отладке приложения все нормально. Но при запуске готового файла EXE при любой попытке изменить содержимое любой таблицы появляется сообщение

Cursor is read-only

Причина

Это надо понимать буквально. Где-то, как-то, Вы изменили статус своих рабочих таблиц таким образом, что они получили статус "Read-Only".

Решение
Решение зависит от причины, по которой таблицы получили статус Read-Only

Вы включили свои таблицы внутрь проекта

Чтобы убедится в этом, откройте окно вашего проекта и найдите нужную таблицу. Слева от имени таблицы должен стоять значок перечеркнутого кружочка. Если это не так, то щелкните правой кнопкой мыши по имени таблицы и в появившемся меню выберите пункт "Exclude". После этого перекомпилируйте проект (заново постройте EXE).

Включение какого-либо файла внутрь EXE осуществляется аналогично. Правой кнопкой мыши по имени и в открывшемся меню выбрать пункт "Include".

Надо понимать, что включение какого-либо файла внутрь EXE означает, что этот файл становится частью EXE и его модификация недопустима. Это можно использовать как примитивный способ защиты своих данных, если эти данные предоставляются только на чтение.

Соответственно, файл, включенный внутрь EXE не надо поставлять клиенту (он и так находится внутри EXE).

Перенос базы данных клиенту на лазерном диске

Дело в том, что в момент записи на лазерный диск всем файлам автоматически устанавливают признак Read-Only. Соответственно после копирования на жесткий диск у клиента этот признак необходимо снять.

Правой кнопкой мыши в "Проводнике" (Explorer-Windows) на имени файла, в появившемся меню выбрать пункт "Свойства" (Properties) и снять птичку "Только чтение" ("Read-Only"). Если предварительно выделить несколько файлов, то свойства будут распространены на все выделенные файлы.

Настройка прав доступа пользователей

Возможно, папка, в которой расположены файлы DBF администратором была выдана в общее пользование со статусом Read-Only. В этом случае необходимо обратится к администратору с просьбой изменить права доступа.

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

НЕ МОГУ ВЫЙТИ ИЗ FOXPRO. ЗАКРЫТЬ ПРИЛОЖЕНИЕ

Проблема
Приложение FoxPro нормально запускается, но когда я хочу из него выйти, например, нажав на "крестик" в правом верхнем углу основного окна, то я получаю сообщение об ошибке

Cann't quit Visual FoxPro

Или, в старших версиях без сокращений

Can not quit Visual FoxPro

Также возможна ситуация, когда приложение FoxPro закрывается, но остается "висеть" в списке запущенных процессов. Т.е. его не видно на панели задач, но можно увидеть в списке процессов (Ctrl+Shift+Esc, закладка "Процессы")

Причина

Скорее всего, Вы забыли прервать режим ожидания событий инициированных пользователем. Т.е. отменить действие команды READ EVENTS

Решение

Перед закрытием приложения надо дать команду

CLEAR EVENTS

Если закрытие приложения происходит по нажатию "крестика" в правом верхнем углу основного окна FoxPro, то это событие перехватывается настройкой

ON SHUTDOWN

Более подробно этот вопрос рассматривается в статье:

Главный (стартовый) файл проекта

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

ОКНО FOXPRO МЕЛЬКАЕТ НА ЭКРАНЕ И ТУТ ЖЕ ЗАКРЫВАЕТСЯ

Проблема

При отладке приложения все в порядке. А когда запускаю готовый файл EXE, мое приложение мелькает на экране и тут же закрывается.

Причина

Скорее всего, Вы забыли сформировать режим ожидания событий, инициированных пользователем. Проще говоря, не указали программе, где она должна остановиться и подождать реакции пользователя. На этапе отладки приложения такой "точкой останова" является ранее запущенная среда FoxPro. Но в готовом приложении этого нет.

Решение
Необходимо сформировать режим ожидания событий, инициированных пользователем. Штатным средством для этого является команда

READ EVENTS

Более подробно этот вопрос рассматривается в статье:

Главный (стартовый) файл проекта

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Как перенести готовое приложение на машину клиента

Вопрос

Я написал (а) приложение на FoxPro и создал (а) исполняемый файл EXE. Однако при попытке запуска на машине клиента я получаю сообщение о том, что нет каких-то библиотек. Какие библиотеки он требует? Как правильно установить готовое приложение на машине клиента?

Ответ

Готовое приложение Visual FoxPro для своей работы требует несколько библиотек поддержки. О некоторых из них, Вы можете узнать непосредственно в HELP для Visual FoxPro в разделе с названием

Visual FoxPro Run-Time Libraries

Откройте HELP для Visual FoxPro и введите название раздела в кавычках в окно поиска. В этой статье приводится список некоторых библиотек. Более того, не все, приведенные в этом разделе библиотеки действительно нужно переносить на машину клиента.

Поэтому, лучше не играть в "угадайку", копируя файлы поштучно, а создать полноценный дистрибутив Вашего приложения.

До версии Visual FoxPro 6 включительно, для создания дистрибутивов использовался встроенный инструмент. Пункт главного меню Tools - Wizards - Setup. Однако, начиная с версии Visual FoxPro 7, используется внешняя программа, под названием "InstallShield". Эта программа (точнее, ее усеченная версия "Express") поставляется вместе с FoxPro на том же диске.

Если Вы работаете со старой версией FoxPro и используете для создания дистрибутива встроенный Wizard, то следует понимать, что этот Wizard создавался с учетом только тех операционных систем, которые существовали на момент выхода соответствующей версии FoxPro. Это значит, что дистрибутив, созданный таким встроенным Wizard может не установиться на машинах с новейшими операционными системами.

Также почитайте статью на данном сайте:

Как сделать exe файл

В качестве программы для создания инсталляционных пакетов (дистрибутивов) хорошо зарекомендовала себя программа InnoSetup. Вы можете скачать его с данного сайта из раздела "Файловый архив", подраздел "Installer"

Если все-таки решили переносить приложение путем копирования файлов, то список необходимых библиотек и куда их надо класть можно посмотреть здесь

VFP 7 Runtime Files
VFP 8 Runtime Files
VFP 9 Runtime Files

Автор публикации

не в сети 3 месяца

Joys

Комментарии: 2Публикации: 177Регистрация: 25-06-2000

(далее…)

Как перевести координату в пикселях (Pixcels) в твипы (Twips)

Проблема

Многие ActiveX компоненты требуют для указания в качестве параметров своих методов координаты в твипах (Twips), но FoxPro дает координаты в пикселах (Pixcels). Как перевести одно в другое?

Решение

Для того, чтобы каждый раз не пересчитывать коэффициенты заново, создайте свойства nTwipX и nTwipY для хранения переводных коэффициентов по X (по вертикали) и по Y (по горизонтали) соответствеенно.

Тогда следующий код следует выполнить в событии Init того объекта, где созданы эти свойтсва.

  
 * Следующие API функции используются для расчета переводного коэффициента    
  DECLARE INTEGER GetActiveWindow IN WIN32API    
  DECLARE INTEGER GetDC IN WIN32API INTEGER iHDC    
  DECLARE INTEGER GetDeviceCaps IN WIN32API INTEGER iHDC, INTEGER iIndex    
        
  LOCAL liHDC    
  liHDC = GetDC(GetActiveWindow())    
  This.nTwipX = 1440/GetDeviceCaps(m.liHDC,88)    
  This.nTwipY = 1440/GetDeviceCaps(m.liHDC,90)    
        
 * Освобождение контекста устройства, для освобождения памяти    
  DECLARE INTEGER ReleaseDC IN WIN32API INTEGER, INTEGER     
  =ReleaseDC(GetActiveWindow(),m.liHDC)

Здесь This.nTwipX и This.nTwipY - это как раз те самые коэффициенты перевода из пикселей в твипы. В данном случае оформлены как дополнительные свойства объекта.

  
  Координата_по_Х_в_твипах = This.nTwipX * координата_по_X_в_пикселях   
  Координата_по_Y_в_твипах = This.nTwipY * координата_по_Y_в_пикселях

В большинстве случаев, эти коэффициенты равны 15

Данный код несколько избыточный в части использования функции GetActiveWindow(). Дело в том, что эта функция возвращает, так называемое HWND-окна (некий числовой идентификатор окна).

Но все дело в том, что многие ActiveX имеют свойство, возвращающее значение их HWND, а, начиная с версии Visual FoxPro 7.0, такое свойство имеют и формы собственно FoxPro. Т.е. Вы можете вместо функции GetActiveWindow() напрямую использовать свойство HWND нужного объекта. Впрочем, и в таком виде данный код вполне работоспособен.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

На машине клиента ActiveX требует лицензию

Проблема.

Я использовал в своей программе ActiveX-компонент, а на машине клиента он не работает. Требует какую-то лицензию.

Причина.

Причина заключается в некоторых юридических тонкостях прав, на использование ActiveX-компонент, реализованных Microsoft. Приблизительно, смысл этих юридических тонкостей можно сформулировать так: нельзя распространять чужой продукт, но можно распространять результат его работы.

Решение.

Необходимо включить используемый ActiveX-компонент в визуальную библиотеку FoxPro (файл VCX). Такое использование ActiveX-компонентов не считается "распространением чужого продукта" и не требует установку лицензии. На машину клиента необходимо перенести только собственно файл OCX, содержащий этот ActiveX-компонент.

Разумеется, после переноса этот файл OCX необходимо зарегистрировать при помощи программы RegSvr32.exe примерно так

regsvr32.exe C:\Windows\System32\Имя_файла.OCX

Здесь вместо текста "Имя_файла" надо написать реальное имя Вашего файла OCX. Файлы OCX, как правило, кладут в директорию System32. Исходя из этого, и написана команда. Но Вы вполне можете положить файл OCX в любое другое место. Соответственно, надо будет подкорректировать команду регистрации.

Любая попытка прямого программного (из файла PRG) создания данного ActiveX-компонента потребует наличия на машине клиента лицензии.

Впрочем, это правило относиться только к тем ActiveX-компонентам, которые созданы собственно Microsoft. Если Вы покупали ActiveX-компонент у стороннего разработчика как отдельный продукт, то Вам следует уточнить у продавца правила распространения программ, использующих данный ActiveX-компонент.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как заменить сообщение Invalid Date при вводе некорректной даты

Вопрос

Если в TextBox вводится некорректная дата, то появляется сообщение "Invalid Date". Как можно проконтролировать корректность ввода даты до появления этого сообщения и заменить данное сообщение своим?

Ответ

Для начала следует задуматься о необходимости такой замены. Дело в том, что если Вы поставляете вместе с готовым файлом EXE русскоязычную Run-Time библиотеку с именем vfpXrrus.dll (X - цифра, соответствующая номеру версии Visual FoxPro), то вместо английского сообщения "Invalid Date" возникнет сообщение по-русски "Неверная дата".

Тем не менее, если Вы все-таки хотите произвести подмену вручную, то для этого есть способ.

Начиная с версии Visual FoxPro 5, для объекта TextBox добавлено свойство StrictDataEntry.

По умолчанию, это свойство имеет значение: 1 - Strict. Установите его в значение: 0 - Loose.

В этом случае, если введено некорректное значение даты, то никакого сообщения об ошибке вообще не возникает. Просто значение свойства TextBox.Value становиться пустым.

Это можно определить в событии TextBox.Valid() и выдать собственное сообщение об ошибке

  
 * Событие TextBox.Valid  
  IF EMPTY(This.Value) = .T.   
  	MessageBox("Дата введена некорректно!")  
  ENDIF

Однако при таком подходе возникают две проблемы:

1) Событие TextBox.Valid() наступает при выходе из объекта вне зависимости от того, изменяли Вы содержимое данного объекта или нет.

Это значит, что если значение поля изначально было пустым и пользователь в нем ничего не менял, а просто "прошел" через этот объект, например, при помощи клавиши Tab, то возникнет сообщение об ошибке. Чего быть не должно.

2) Если изначально дата уже была введена, а в процессе изменения пользователь ошибся, то желательно установить не пустое значение даты, а вернуть ее в исходное состояние. Т.е. установить то значение, которое было до редактирования.

Чтобы решить эти проблемы необходимо небольшое пояснение.

Если пользователь что-то изменяет в объекте, то на каждую модификацию срабатывает событие TextBox.InteractiveChage(). Но в данном случае недостаточно просто определить факт модификации. Необходимо определить тот факт, что пользователь пытался ввести не пустое значение.

То, что пользователь пытался ввести сохраняется в свойстве TextBox.Text. Точнее, в этом свойстве хранится то, что пользователь видит на экране, а не то, что сохраняется в свойстве TextBox.Value. Хотя значение этих свойств могут и совпадать. Но в общем случае это не так. Они отличаются, например, из-за используемых масок ввода.

К сожалению, нельзя просто сравнить в событии TextBox.Valid() значение свойств TextBox.Value и TextBox.Text. Дело в том, что если объект TextBox имеет не пустое значение свойства TextBox.ControlSource (например, TextBox "привязан" к полю таблицы), то к моменту выполнения события TextBox.Valid() в случае ошибки ввода свойство TextBox.Text также окажется пустым. Отдельное спасибо Андрею Тарасову (XAndy), обратившему на это внимание.

Следовательно, необходимо в событии TextBox.InteractiveChange() организовать сохранение текущего значения свойства TextBox.Text. И если в событии TextBox.Valid() окажется, что значение TextBox.Value пустое, а сохраненное значение TextBox.Text не пустое, то это и будет означать ошибку ввода.

Аналогичным образом следует поступить и для восстановления значения до редактирования. Надо просто сохранить исходное значение. Процедуру сохранения выполнить при входе в объект. Либо в событии TextBox.When(), либо в событии TextBox.GotFocus().

У любого объекта FoxPro есть два дополнительных свойства: Tag и Comment. Это свойства-комментарии. Они никак не влияют на работу объекта и предназначены для хранения справочной информации. Следует только иметь в виду, что они принимают значения только и исключительно символьного типа. Вот эти-то два свойства и используем для хранения нужных значений.

В результате, после всех пояснений, получаем такой код:

  
 * Событие TextBox.When  
  This.Comment = DTOC(This.Value)  
    
    
 * Событие TextBox.InteractiveChange  
 * Используется TransForm(), а не DTOC(),   
 * поскольку значение This.Text может не преобразовываться в дату  
  This.Tag = TransForm(This.Text)  
    
    
 * Событие TextBox.Valid  
 * Значение, которое попытался ввести пользователь  
  LOCAL lcUserText  
  lcUserText = This.Tag  
    
 * Очищаем сохраненное значение  
  This.Tag = ""  
    
 * Сравниваю то, что реально введено с тем, что пытались ввести   
 * Предполагаю, что реально введено то, что должно вернуть Ctod(m.lcUserText)  
  If Empty(m.lcUserText)=.F. AND m.lcUserText <> Dtoc(Ctod(m.lcUserText))  
  	This.Value = Ctod(This.Comment)  
  	MessageBox("Неверный ввод даты")  
  	  
 	* Если хотите запретить выход из объекта,   
 	* то снимите комментарий со следующей команды  
 	* Return 0  
  EndIf

Вам решать, стоит ли полученный результат затраченных усилий.

Замечание

Если объект TextBox, не связан ни с каким источником данных. Т.е. и TextBox.ControlSource, и TextBox.Value при открытии формы не указаны. То для того, чтобы символы разделители в дате не съезжали при вводе, необходимо указать нужный формат

TextBox.Format = "D"

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как заставить клавишу с “точкой” всегда вводить точку

Вопрос

На альтернативной цифровой клавиатуре (правая часть клавиатуры под клавишей NumLock) есть клавиша с "точкой". Однако она водит именно точку только при английской раскладке клавиатуры, а при русской раскладке клавиатуры вводит запятую. При вводе чисел с дробной частью это создает проблемы. Как можно заставить вводить символ точки вне зависимости от текущей раскладки клавиатуры?

Ответ

В событии KeyPress для Вашего объекта TextBox пишете такой код

  
  LPARAMETERS nKeyCode, nShiftAltCtrl  
  IF InList(CHR(nKeyCode),'.',',') AND CHR(nKeyCode)<>SET('POINT')  
  	NODEFAULT  
  	DoDefault(ASC(SET('POINT')),nShiftAltCtrl)  
    
 	*!* или вместо DoDefault в данном случае можно дать такую команду  
 	*!* KeyBoard SET('POINT') PLAIN CLEAR  
  ENDIF

Все. Теперь при попытке ввода точки или запятой будет автоматически введен символ, который Вы приняли в качестве разделителя целой и дробной части. Даже если это, например, дефис.

Для удобства работы, лучше создать отдельный класс на основе TextBox с данным кодом, чтобы не дублировать его каждый раз при создании нового объекта.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

При запуске отчета из формы формируются неверные данные

Проблема:

На этапе подготовки и отладки отчета - все нормально, но когда готовый отчет запускается из формы приложения отчет либо выдает сообщения об ошибках, либо формирует некорректные данные.

Причина:

Отчет это всегда сканирование одной главной таблицы. Для корректной работы отчеты он должен обязательно перейти в рабочую область этой главной таблицы.

Если по каким-либо причинам этого не происходит, то в процессе выполнения отчета он начинает сканировать ту таблицу, которая оказалась в текущей рабочей области. В этом случае результат выполнения отчета становится не предсказуемым.

Решение:

Способ решения зависит от того, по какой причине оказалась потеряна (не выбрана) главная таблица отчета.

Наиболее вероятными являются следующие причины:

1. В момент вызова отчета фокус находится в объекте Grid
2. При создании отчета не была явно указана главная таблица отчета
3. Главная таблица отчета не была открыта или не видна из отчета

1. В момент вызова отчета фокус находится в объекте Grid.

Это BUG (глюк) FoxPro. Причина такого поведения не вполне понятна, но если в момент вызова отчета фокус находится в объекте Grid, то объект Grid "не отпускает" текущую рабочую область.

Решение сводится к тому, чтобы перед выполнением отчета увести фокус с объекта Grid на любой другой объект формы. Если кроме собственно объекта Grid на форме ничего нет, то создайте специальный объект TextBox или CommandButton за границами видимой части окна (Top = -100, Left = -100) и передавайте фокус на этот "невидимый" объект непосредственно перед вызовом отчета:

  
  ThisForm.Command1.SetFocus()  
  REPORT FORM MyReport.frx  
  ThisForm.Grid1.SetFocus()

2. При создании отчета не была явно указана главная таблица отчета.

Как правило, если Вы используете DataEnvironment отчета, то по-умолчанию главной таблицей отчета становится первая таблица, физически добавленная в DataEnvironment. Однако если по какой-либо причине это не устраивает, то главную таблицу можно указать явно в свойствах собственно DataEnvironment отчета. За это отвечает свойство:

Report.DataEnvironment.InitialSelectedAlias

Это свойство принимает значение алиаса одной из таблиц, добавленных в DataEnvironment собственно отчета. Выбранный алиас и назначается "главной" таблицей отчета.

Если же Вы не используете DataEnvironment отчета, то следует принудительно перейти в рабочую область главной таблицы непосредственно перед вызовом отчета

  
  Select MainTab  
  REPORT FORM MyReport.frx

3. Главная таблица отчета не была открыта или не видна из отчета.

Подобная ситуация возможна, если Вы не используете DataEnvironment отчета или же установили его свойство

Report.DataEnvironment.AutoOpenTables = .F.

Это означает, что Вы полностью берете на себя ответственность за установку среды окружения отчета на себя. Другими словами, Вам необходимо самостоятельно проверить факт наличия нужных таблиц и открыть их, если это необходимо до того, как отчет начнет выполняться.

Как правило, подобная ситуация возникает, если в качестве источника данных для отчета используется курсор, которого просто не существует как объект, который можно было бы добавить в DataEnvironment отчета.

Но не просто факт использования курсора (это довольно легко определяется), а запуск отчета в Private DataSession. Это настраивается в режиме модификации отчета: пункт меню Report - Private DataSession.

Вообще-то, сама по себе идея запуска отчета в Private DataSession очень хорошая. Работа отчета происходит независимо от работы форм. Но применительно к курсорам следует помнить, что курсор созданный в одной DataSession "не виден" в другой DataSession. А установка свойства Private DataSession, как раз и означает, что отчет будет запущен в "другой" DataSession.

В этом случае формирование курсоров надо перенести извне отчета в методы самого отчета. Как правило, это делается в методах DataEnvironment отчета. Например, в методе

Report.DataEnvironment.BeforeOpenTables

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как запретить печать из окна предварительного просмотра

Вопрос

Как запретить печать из окна предварительного просмотра?

Ответ

Данная проблема имеет несколько решений, но наиболее корректным является удаление кнопки с изображением принтера из окна предварительного просмотра. Это можно сделать при помощи специально созданного файла ресурсов.

Файл ресурсов, по умолчанию, это файл FoxUser.dbf (fpt). Он хранит настройки всех когда-либо открытых окон в среде FoxPro.

Сначала создадим копию ресурсного файла:

  
  SELECT 0  
  USE (SYS(2005)) AGAIN  
  COPY TO NoPrint.dbf  
  USE

В результате получится копия ресурсного файла в текущей директории с именем NoPrint.dbf

Устанавливаем в качестве реусрсного файла этот вновь созданный файл.

  
  gcResource=SYS(2005)   && сохраняю путь к старому ресурсному файлу  
  SET RESOURCE TO NoPrint.dbf

Далее выбираем пункт главного меню View->ToolBars... Убедитесь, что стоит крестик в пункте "Print Preview" и нажмите кнопку "Customize..."

Теперь нажмите левой кнопкой мыши кнопку с изображеним принтера в ToolBar "Print Preview" и не отпуская перетащите ее за пределы этого ToolBar. Все, кнопка удалена из этого ToolBar и такое состояние сохранено в текущем файле ресурсов.

Восстанавливаем исходный файл ресурсов

SET RESOURCE TO (m.gcResource)

Следует заметить, что внутри файла ресурсов много самой разнообразной информации, которая собственно не нужна в данной задаче. Поэтому для экономи места все лишнее можно удалить. Для этого откройте новый файл ресурсов

USE NoPrint.dbf

И найдите в нем не удаленную запись со следующими значениями полей:

  
  TYPE="PREFW"  
  ID="TTOOLBAR"  
  NAME="Print Preview"

Все остальные записи можно смело удалять. Они никак не влияют на данный ToolBar.

В принципе, этот файл ресурсов (вместе с мемо-полем) можно включить внутрь проекта, чтобы не поставлять отдельно кучу ресурсных файлов.

Собственно запуск отчета с использованием только что созданного файла ресурсов примет вид:

  
 * Запоминаю старый файл ресурсов  
  LOCAL lcResource  
  lcResource=SYS(2005)  
 * Подключаю нужный ресурсный файл  
  SET RESOURCE TO NoPrint.dbf  
    
 * Выполняю отчет  
  REPORT FORM MyReport.frx NOCONSOLE PREVIEW  
    
 * Восстанавливаю старый ресурсный файл  
  SET RESOURCE TO (m.lcResource)

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как отобразить окно предварительного просмотра в As Top-Level форме

Вопрос

Приложение написано на базе As Top-Level форм. При вызове отчета на предварительный просмотр он вообще не появляется. В чем причина? Как можно отобразить окно предварительного просмотра.

Причина

Для версий до Visual FoxPro 6 включительно, по умолчанию, окно предварительного просмотра открывается In-Screen. Т.е. внутри основного окна FoxPro.

Решение

Необходимо перенаправить вывод окна предварительного просмотра в окно, созданное на базе As Top-Level формы. Это стало возможным только с появлением опции IN WINDOW в Visual FoxPro 6.

Пример решения описан в статье Q188887, на сайте Microsoft

How to display the Print Preview window in a top-level form in Visual FoxPro

Суть приведенного там примера заключается в следующем коде

  
  oPForm = CREATEOBJECT('printpreview')  
  oPform.visible = .t.    && Открыть форму в которую пойдет вывод  
 *******  
 * Следующая команда использует опцию IN WINDOW  
 * Заметьте, что использована как опция WINDOW, так и опция IN WINDOW  
 * Опция WINDOW устанавливает для окна предварительного просмотра  
 * те же характеристики, что и у указанного окна, в то время как   
 * опция IN WINDOW говорит о том, внутри какого окна следует открывать  
 * окно предварительного просмотра  
 *******  
  REPORT FORM report_1 PREVIEW WINDOW printpreview IN WINDOW printpreview  
    
 * Класс окна предварительного просмотра  
  DEFINE CLASS printpreview AS form  
    
  ScaleMode = 3  
  Top = 0  
  Left = 0  
  Height = 454  
  Width = 641  
  ShowWindow = 2  
  DoCreate = .T.  
  Caption = "Print Preview Window"  
  Movable = .T.  
  TitleBar = 0  
  WindowState = 0  
  SizeBox = .F.  
  Name = "printpreview"  
    
  ENDDEFINE

Разумеется, Вы можете создать нужный класс в визуальной библиотеке классов. Можете использовать для опции Window одно окно, а для опции IN WINDOW - другое. Это просто пример.

Замечание

Опция IN WINDOW была добавлена только в версии Visual FoxPro 6. Для младших версий FoxPro придется, так или иначе, использовать основное окно FoxPro.

Т.е. перед открытием окна предварительного просмотра отобразить основное окно FoxPro, а после просмотра - закрыть.

  
  _SCREEN.Visible = .T.  
  REPORT FORM MyReport.frx  
  _SCREEN.Visible = .F.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как выбрать принтер из окна предварительного просмотра

Вопрос

При открытии отчета на предварительный просмотр и последующего нажатия кнопки с изображением принтера не появляется окно настройки принтера. Печать идет на принтер по умолчанию. Как можно вызвать окно настройки принтера из режима предварительного просмотра?

Ответ

Для предварительного просмотра отчета, как правило, подается команда

REPORT FORM MyReport.frx PREVIEW

Отчет будет выдан на экран вместе с командной кнопкой с изображением принтера, по нажатию на которую будет выполнена печать на бумагу.

Однако в этом случае пользователь не получит приглашение по выбору и настройке принтера. Печать пойдет на принтер по умолчанию, и будут использованы его настройки по умолчанию.

Чтобы пользователь получил возможность выбора принтера и его настроек используйте команду

REPORT FORM MyReport.frx TO PRINTER PROMPT PREVIEW

Обратите внимание на порядок следования опций. "PREVIEW" должна следовать после опций "TO PRINTER PROMPT". В противном случае, вы получите сообщение об ошибке при попытке выполнить команду.

Замечание

Этот совет не применим к версиям FoxPro 2.x, а также в том случае, если в команде REPORT FORM используется опция NOWAIT.

Однако в версии Visual FoxPro 9 даже при использовании опции NOWAIT можно вызвать окно предварительной настройки принтера по приведенной выше схеме если предварительно сделать дополнительную настройку

  
  SET ReportBehavior 90  
  REPORT FORM MyReport.frx TO PRINTER PROMPT PREVIEW NOWAIT

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

VFP8 некорректно отображает содержимое отчета

Проблема.

При выполнении отчета в среде Visual FoxPro 8.0 буквы наезжают друг на друга или отображаются непонятные "закорючки"

Причина.

Причина связана с тем, что в Visual FoxPro 8 как-то изменили обработку отчетов, использующих TrueType - шрифты в случае оптимизации печати принтером. Т.е. это ситуации, когда принтер пытается печатать такие шрифты не как графику, а используя некую внутреннюю библиотеку шрифтов.

Решение.

Есть несколько решений

1. Отказаться от использования TrueType-шрифтов
2. Изменить настройки драйвера принтера у клиента
3. Принудительно изменить настройки каждого файла отчета

Отказаться от использования TrueType-шрифтов.

Данный совет трудно исполним на практике. Как правило, при подготовке отчетов используют несколько видов шрифтов. Сложно найти адекватную замену TrueType-шрифтам.

В идеале, желательно создать собственные шрифты. Но далеко не каждый программист на это способен.

Изменить настройки драйвера принтера у клиента.

В операционных системах Windows 95 или Windows 98 необходимо установить печать шрифтов в виде графики. Для старших версий операционной системы такого переключателя нет. Там необходимо отключить оптимизацию печати.

Проблема только в том, что это "внешние" по отношению к самой программе настройки. А это значит, что проконтролировать их значение у клиента практически невозможно. Тем более некорректно требовать принудительного задания настроек внешних устройств только для того, чтобы корректно работала одна из многих программ, установленная на компьютере клиента.

Принудительно изменить настройки каждого файла отчета.

А вот это то, что может реально сделать разработчик программы, хотя это достаточно кропотливое занятие, требующее от программиста повышенной бдительности.

Физически, файлы отчетов FoxPro - это обычные DBF-таблицы. Просто у них изменено расширение. DBF - FRX, FPT - FRT.

Вам следует открыть файл отчета как таблицу командой

  
  USE MyReport.frx  
  BROWSE

В этой команде следует обязательно указать расширение файла отчета "FRX". В противном случае, FoxPro посчитает, что речь идет о файле с расширением DBF.

Теперь находите в этом файле запись со значениями полей

  
  ObjType = 1  
  ObjCode = 53

Как правило, это физически самая первая запись.

Откройте на редактирование в этой записи Memo-поле с именем Expr. Найдите (или создайте) строку, начинающуюся с ключевого слова TTOPTION и установите значение

TTOPTION=1

Это и означает команду принтеру печатать TrueType-шрифты как графику. Сохраните внесенные изменения и закройте файл отчета.

Недостаток данного решения в том, что после каждой модификации отчета при помощи дизайнера отчетов эта настройка опять примет значение 2 или 3. Т.е. после каждой модификации отчетов надо не забыть еще раз открыть файл отчета как таблицу и внести нужные изменения.

Кстати, значение TTOPTION = 2 - это значение по умолчанию, для принтеров Hewlett-Packard использующих Printer Control Language (PCL). Именно поэтому данная проблема чаще всего встречается при работе с принтерами Hewlett-Packard.

Достаточно подробно данная проблема обсуждалась на этом сайте. Можете почитать дискуссию по приведенной ссылке

forum.foxclub.ru

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Неустранимая ошибка при выполнении отчета

Проблема

При работе в Visual FoxPro 5.0 или Visual FoxPro 6.0 запуск на выполнение готового отчета приводит к неустранимой ошибке и прерыванию выполнения приложения. Как правило, это происходит в операционных системах Windows 95 или Windows 98. Хотя для версии Visual FoxPro 5.0 это может произойти на любой операционной системе.

Причина

Причина заключается в конфликте использования сопроцессора собственно FoxPro и текущим драйвером принтера.

Решение

Решение заключается либо в отключении сопроцессора (это можно сделать через панель управления), либо в принудительной его очистке при помощи специальной библиотеки

  
  DECLARE _fpreset IN msvcrt20.dll  
  =_fpreset()  
 * Запуск на выполнение отчета  
  REPORT FORM MyReport.frx  
  =_fpreset()

Подробнее об этой ошибке можно прочитать в базе знаний на сайте MicroSoft. Статья Q183522

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как из модальной формы, открытой через Show(1) вернуть значение

Вопрос:

Я создал класс формы и создаю экземпляр модальной формы командой

  
  LOCAL loForm  
  loForm = CreateObject("MyFormClass")  
  m.loForm.Show(1)

Как из такой формы вернуть значение?

Ответ:

Идея решения принадлежит Вадиму Пирожкову (Piva).

Суть решения сводится к тому, что форма не может быть уничтожена, пока существует хотя бы одна ссылка на эту форму. Эта дополнительная ссылка создается при помощи объектных скобок WITH...ENDWITH.

Создание экземпляра такой формы примет вид:

  
  LOCAL loForm, lvProp1, lvProp2  
  loForm = CreateObject("MyFormClass")  
  WITH m.loForm  
  	.Show(1)  
  	m.lvProp1 = .Text1.Value  
  	m.lvProp2 = .Prop2  
  ENDWITH

Здесь Text1 – это объект, расположенный на форме, а Prop2 – свойство самой формы.

До тех пор, пока не будет закрыта объектная скобка "ENDWITH" форма не может быть удалена. Следовательно, будут доступны для прямого чтения все ее свойства и методы.

Но если форма не может быть удалена, то прямая команда ThisForm.Release() будет проигнорирована или же ее выполнение приведет к различным глюкам.

Чтобы все-таки удалить форму используется другая особенность модальных форм в FoxPro.

Модальной может быть только видимая форма. Как только модальная форма перестает быть видимой, она перестает быть модальной.

Другими словами, закрытие формы осуществляется не одной, а двумя командами:

  
  ThisForm.Hide()  
  ThisForm.Release()

Замечание:

В принципе, можно обойтись и без дополнительной объектной переменной для вызова формы. Примерно так:

  
  LOCAL lvProp1, lvProp2  
  WITH CreateObject("MyFormClass")  
  	.Show(1)  
  	m.lvProp1 = .Text1.Value  
  	m.lvProp2 = .Prop2  
  ENDWITH

Это как Вам покажется удобнее. Надо только не забыть присвоить "внешним" (по отношению к объектной скобке WITH...ENDWITH) переменным значения свойств модальной формы.

Темы, связанные с данной:

Что означает префикс (буква) "m." перед именем

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как из модальной формы вернуть несколько значений

Вопрос:Запускаю модальную форму командой:

DO FORM MyForm.scx TO m.MyVar

В переменную m.MyVar будет записано одно возвращаемое значение. А как вернуть из модальной формы несколько значений? Как вернуть из модальной формы массив?

Ответ:

Идея решения принадлежит Юрию Шутенко (JS).

Суть идеи заключается в том, что хотя FoxPro ограничивается одним возвращаемым значением, но не накладывается никаких ограничений на тип этого возвращаемого значения. В данном случае, следует в качестве возвращаемого значения воспользоваться переменной типа "Object".

В событии UNLOAD формы пишется примерно такой код:

  
 * Создаем переменную типа "Object"  
  LOCAL loReturnValue   
  loReturnValue = CreateObject("Empty")  
    
 * Формируем в этой переменной нужное количество свойств  
 * и записываем в них нужные значения  
  AddProperty(m.loReturnValue,"Prop1")  
  m.loReturnValue.Prop1 = "Первое значение"  
    
  AddProperty(m.loReturnValue,"Prop2")  
  m.loReturnValue.Prop2 = "Второе значение"  
    
 * Добавляем свойство типа "массив"  
  AddProperty(m.loReturnValue,"PropArray[2,2]")  
  m.loReturnValue.PropArray[1,1] = 1  
  m.loReturnValue.PropArray[1,2] = 2  
  m.loReturnValue.PropArray[2,1] = 3  
  m.loReturnValue.PropArray[2,2] = 4  
    
  RETURN m.loReturnValue

Вызов такой формы и разбор возвращаемых параметров примет такой вид

  
  LOCAL loNewValue  
  loNewValue = NULL  
    
  DO FORM MyForm.scx TO m.loNewValue  
    
 * Переписываем возвращенные значения из свойств объекта в переменные памяти  
  LOCAL lcVal1, lcVal2, laArray(2,2)  
  lcVal1 = m.loNewValue.Prop1  
  lcVal2 = m.loNewValue.Prop2  
  =ACOPY(m.loNewValue.PropArray, m.laArray)

Впрочем, можно и не переписывать значений из свойств полученного объекта в переменные памяти. Это уже зависит от конкретной задачи.

Замечание:

Объект класса "Empty" и функция AddProperty() были введены в FoxPro в версии Visual FoxPro 8. Для младших версий FoxPro в качестве возвращаемого объекта можно использовать объект класса "Custom", а для создания новых свойств его метод Custom.AdProperty().

  
 * Создаем переменную типа "Object"  
  LOCAL loReturnValue   
  loReturnValue = CreateObject("Custom")  
    
 * Формируем в этой переменной нужное количество свойств  
 * и записываем в них нужные значения  
  m.loReturnValue.AddProperty("Prop1")  
  m.loReturnValue.Prop1 = "Первое значение"  
    
  ...

Метод AddProperty() был введен в FoxPro в версии Visual FoxPro 6. Для младших версий FoxPro нужное количество свойств возвращаемого объекта, да и сам объект, необходимо сформировать заранее в соответствующей библиотеке классов.

Темы, связанные с данной:

Что означает префикс (буква) "m." перед именем

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Почему параметры, переданные в форму “видно” только в INIT-формы

Вопрос
Я передаю параметры в форму. Они принимаются в событии INIT-формы и там они имеют переданные значения. Почему эти же переданные значения не "видно" из других методов формы?

Ответ

Дело в том, что параметр - это переменная памяти. Как и любая другая переменная памяти, она имеет область видимости. Если параметры принимаются через команду PARAMETERS, то область видимости PRIVATE. А если через команду LPARAMETRS, то область видимости LOCAL.

Кроме того, следует учитывать тот факт, что даже события, выполняющиеся при инициализации формы, выполняются не друг ИЗ друга, а друг ЗА другом. Т.е. это не вложенные друг в друга процедуры, а последовательность процедур.

Следовательно, в общем случае, даже переменная с областью видимости PRIVATE, объявленная в одном из событий или методов формы, не будет "видна", ни в каком другом событии или методе формы.

Чтобы обойти это ограничение, следует в том же событии INIT-формы присвоить переданные через параметры значения специально созданным свойствам (properties) формы. Как это сделать, подробно описано здесь

Почему созданный массив или переменную не "видно" в других методах формы

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как перехватить нажатие на крестик в правом верхнем углу формы

Вопрос

Как перехватить нажатие на крестик в правом верхнем углу формы?

Ответ

При нажатии на крестик в правом верхнем углу формы срабатывает событие формы QueryUnload(). Если в этом событии дать команду

NODEFAULT

то закрытие формы будет отменено. Т.е. можно попросить пользователя подтвердить желание закрыть форму.

*** Событие формы QueryUnload  
  IF MessageBox("Вы действительно хотите закрыть форму",4+32+256,"Закрытие формы")=7  
 	* Нажали кнопку "Нет"  
  	NODEFAULT  
  ENDIF

Если у Вас на форме предусмотрена специальная кнопка "Выход", по нажатию на которую происходит закрытие формы, то, для того, чтобы не дублировать один и тот же код в несколких местах просто делайте вызов события нажатия данной кнопки при нажатии на крестик. Примерно так:

*** Событие формы QueryUnload  
  NODEFAULT  
  ThisForm.CmdExit.Click()

Здесь CmdExit - это имя кнопки "Выход".

Следует иметь в виду, что при вызове метода Release() или использовании команды RELEASE для закрытия формы событие QueryUnload() будет проигнорировано. Т.е. не сработает.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Почему созданный массив или переменную не “видно” в других методах формы

Проблема

В одном из методов формы или одного из ее объектов я создаю массив или переменную. Почему я не могу использовать этот массив или переменную в других методах и событиях, как самой формы, так и ее объектов. Например, как источник данных для ComboBox.

Причина

По умолчанию, если область видимости переменной памяти или массива не указана явно через команды PUBLIC, PRIVATE или LOCAL, то для такой переменной памяти или массива устанавливается область видимости PRIVATE. Т.е. команда DIMENSION (DECLARE) создаст массив с областью видимости PRIVATE.

Это значит, что созданный в методе формы или одного из ее объектов массив будет автоматически уничтожен по завершении того метода, в котором этот массив был создан.

Решение

Есть два принципиальных способа решения

1. Установить область видимости массива PUBLIC
2. Создать дополнительное свойство (Property) типа массив

По ряду причин, назначение локальному объекту области видимости PUBLIC - это не очень хорошая идея. В данном случае, под "локальным объектом" подразумевается массив, поскольку он нужен "локально", в пределах одной формы.

Наилучшим решением будет создание дополнительного свойства (Property) типа массив. Такое свойство можно создать как программно, используя метод AddProperty(), так и в дизайнере формы через пункт меню "Form", подпункт "New Property" или "Edit Property/Method".

Признаком того, что данное свойство является массивом, служит указание размерности. Например:

ThisForm.AddProperty("aArray[1,1]")

Размерность такого массива впоследствии можно изменять программно, через команду Dimension. Например:

DIMENSION ThisForm.aArray(10,2)

Теперь Вы можете из любого объекта формы обратиться к данному массиву, поскольку он является неотъемлемой частью самой формы.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

В готовом EXE все меню или его часть отображается не по русски

Проблема

При переносе готового приложения на машину клиента все меню или его часть отображается не по русски или непонятными закорючками.

Причина

Причин данной проблемы может быть несколько. Но наиболее вероятная - это изменение тем рабочего стола. Точнее, не был указан вообще, или указан какой-либо специфический шрифт для отображения меню.

Решение

Установите корректный шрифт меню для используемой темы рабочего стола. Обычно это шрифт Tahoma, 8. Или просто установите какую-либо стандартную тему рабочего стола со шрифтами по умолчанию.

К сожалению, решить данную проблему программно (т.е. явно указать шрифт для меню) можно лишь частично. Можно задать шрифт для выпадающих пунктов меню, но основная линейка меню использует только и исключительно системные настройки. Как это можно сделать посмотрите здесь

Как изменить шрифт пунктов меню в дизайнере меню

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как изменить шрифт пунктов меню в дизайнере меню

Вопрос:

Как изменить шрифт пунктов меню в дизайнере меню?

Ответ:

Непосредственно в дизайнере меню такого пункта нет.

Вероятно, причина в том, что настройки основной линейки меню берутся из системных настроек (из настроек Windows). Т.е. даже если Вы явно укажите свой шрифт для пунктов основной линейки меню, то они будут проигнорированы. Вот разработчики FoxPro и посчитали, что нет смысла вводить настройку, которая все равно игнорируется в основной линейке меню.

Однако для всех прочих пунктов меню все-таки можно явно указать шрифт.

Дело в том, что, то, что формируется в дизайнере меню - это не окончательное меню, а лишь некий "макет" меню. Из этого макета впоследствии формируется окончательное меню, когда Вы выбираете пункт системного меню Menu - Generate. Эта генерация выполняется несколько формально. Чем, в данном случае, и следует воспользоваться.

Выберите нужный Вам пункт меню (исключая пункт основной линейки меню) и нажмите кнопку в столбце "Options".

В разделе SKIP FOR напишите примерно следующее:

.F. FONT "Arial Cyr",20 STYLE "B"

После генерации меню получим в итоговом файле MPR что-то вроде

  
  DEFINE BAR 1 OF пример PROMPT "Пример" ;  
  SKIP FOR .F. "Arial Cyr",20 STYLE "B"

В режиме Preview в самом дизайнере меню Вы не увидите результатов этого "хакерского" трюка. Результат будет виден только при запуске самого меню.

Если по каким-либо причинам, Вы не хотите использовать раздел SKIP FOR для указания шрифта, то примерно, то же самое можно сделать в разделе Message. Только там код будет несколько другим

'' FONT "Arial Cyr",20 STYLE "B"

После генерации меню получим в итоговом файле MPR что-то вроде

  
  DEFINE BAR 1 OF пример PROMPT "Пример" ;  
  MESSAGE '' "Arial Cyr",20 STYLE "B"

Разумеется, для задания шрифта следует использовать только один раздел. Т.е. либо раздел SKIP FOR, либо раздел Message. Не надо указывать шрифт в обоих разделах. Это вызовет синтаксическую ошибку в итоговом меню. Будет одновременно две опции FONT у одного пункта.

Замечание:

Начиная с версии Visual FoxPro 9, в синтаксисе команды DEFINE BAR у опции FONT появился третий необязательный параметр - nFontCharSet. Т.е. можно сделать шрифт меню относительно независимым от региональных настроек системы. Например, для русского языка в разделе SKIP FOR это будет выглядеть примерно так:

.F. FONT "Arial",20,204 STYLE "B"

Более того, генератор меню версии Visual FoxPro 9 стал более "интеллектуальным". Если у него получается конструкция вида SKIP FOR .F., то она просто исключается, и меню будет иметь следующий вид

  
  DEFINE BAR 1 OF пример PROMPT "Пример" ;  
  "Arial",20,204 STYLE "B"

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Почему в готовом EXE не работает копирование по Ctrl+C, Ctrl+V

Проблема

На этапе разработки приложения работало копирование через буфер обмена (горячие клавиши Ctrl+C, Ctrl+V), но в готовом файле EXE эти комбинации клавиш не работают. Как можно исправить эту ситуацию?

Причина

Эти комбинации горячих клавиш связаны с определенными пунктами системного меню. Если в Вашем приложении не предусмотрены данные пункты меню, то и не будет выполнено никаких действий для указанных комбинаций клавиш. Просто не указано, что именно должно выполняться.

Решение

Вам необходимо определить соответствующие пункты меню. Это все те пункты, которые определены в выпадающем меню для пункта системного меню Edit. Обычно этот пункт делается вторым пунктом основной линейки меню. Т.е. в Вашем файле для запуска основного меню должно быть примерно следующий код.

  
 * Первый пункт основной линейки меню  
  DEFINE PAD _msm_edit OF _MSYSMENU PROMPT "Правка" COLOR SCHEME 3  
 * Прочие пункты основной линейки меню  
    
  DEFINE POPUP _medit MARGIN RELATIVE SHADOW COLOR SCHEME 4  
  DEFINE BAR _MED_UNDO OF _medit PROMPT "Отменить" ;  
  	KEY CTRL+Z, "CTRL+Z"  
  DEFINE BAR _MED_REDO OF _medit PROMPT "Вернуть" ;  
  	KEY CTRL+R, "CTRL+R"  
  DEFINE BAR _MED_SP100 OF _medit PROMPT "\-"  
  DEFINE BAR _MED_CUT OF _medit PROMPT "Вырезать" ;  
  	KEY CTRL+X, "CTRL+X"  
  DEFINE BAR _MED_COPY OF _medit PROMPT "Копировать" ;  
  	KEY CTRL+C, "CTRL+C"  
  DEFINE BAR _MED_PASTE OF _medit PROMPT "Вставить" ;  
  	KEY CTRL+V, "CTRL+V"  
  DEFINE BAR _MED_CLEAR OF _medit PROMPT "Очистить"  
  DEFINE BAR _MED_SP200 OF _medit PROMPT "\-"  
  DEFINE BAR _MED_SLCTA OF _medit PROMPT "Выделить все" ;  
  	KEY CTRL+A, "CTRL+A"

Если Вы делаете свое меню, используя, дизайнер меню, то

• Присвоение имени "_msm_edit" производится в окне, которое появляется при нажатии кнопки в столбце "Options" напротив пункта меню "Правка"
• Для присвоения имени выпадающего Popup-меню "_medit" в дизайнере меню войдите в подменю "Правка". Далее выберите пункт системного меню View, подпункт Menu Options и в графе Name впишите значение "_medit" (без кавычек, разумеется)
• Для присвоения имен BAR-пунктам выберите в столбце Result дизайнера меню значение "Bar #" и впишите соответствующие имена в столбце для ввода команд
• Комбинации горячих клавиш назначаются в окне, которое появляется при нажатии кнопки в столбце "Options" напротив соответствующего Bar-пункта меню

  Следует заметить, что для функционирования комбинаций горячих клавиш вовсе не обязательно активировать ранее определенное меню. Достаточно самого факта его определения.

  Впрочем, я бы рекомендовал все-таки его сделать, поскольку сам Pad-пункт главной линейки меню "_msm_edit" - это хорошая "привязка" для динамического добавления "контекстного" меню. Т.е. такого пункта меню, которое появляется только при активации определенных форм.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как добавить в меню список открытых окон

Вопрос

Как добавить в меню список всех открытых окон

Ответ

• В главной линейке меню создаем пункт "Окна"
• В этом пункте меню нажимаем кнопку в столбце "Options"
• В открывшемся окне вводим Pad Name = _msm_windo
• У пункта меню "Окна", оставляем столбец "Result" в значении "SubMenu" и нажимаем кнопку "Edit" для создания подменю
• Необходимо создать в подменю хотя бы один пункт. Например, пункт "Следующее окно", в разделе Result = #Bar, а в качестве значения _MWI_ROTAT
• Теперь выбираем пункт основного меню FoxPro с именем View, подпункт Menu Options
• Вводим значение Name = _MWINDOW

  Все. Теперь в раскрывающемся меню "Окна" будет отображаться список ВСЕХ созданных окон. Даже если это окно не отображается на экране (скрыто).

  Для проверки, дайте в командном окне команду

  DEFINE WINDOW test FROM 0,0 to 10,10

  Окно не активно. Только создано. Тем не менее, уже отображается в списке окон пункта Window. Более того, на него можно переключиться!

  Следует помнить, что при редактировании меню в дизайнере, имя выпадающего Popup-меню автоматически устанавливается равным имени PAD-пункта из которого оно собственно "выпадает". Это значит, что если по каким-либо причинам Вы измените название PAD-пункта. Например, вместо "Окна" напишите "Окно", то имя POPUP-меню автоматически измениться на "Окно". Надо будет не забыть, снова исправить его на _MWINDOW

  Если Вас не устраивает отображение вообще всех открытых окон, то в этом случае Вам придется самостоятельно вести этот список и формировать выпадающее меню динамически.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

При запуске меню появляется сообщение о синтаксической ошибке

Проблема
Создаю меню в дизайнере меню. Но при запуске меню на исполнение появляется сообщение о синтаксической ошибке. Если его проигнорировать, то дальнейшая работа происходит без ошибок.

Причина

Проблема связана с некорректной интерпретацией русских букв в качестве "горячих клавиш" в основной линейке меню.

"Горячая клавиша" - это клавиша или набор клавиш, нажатие на которые вызывает выполнение соответствующего пункта меню без необходимости выбора его мышкой.

Дело в том, что если, для пункта в основной линейке меню явно не указана "горячая клавиша", то по умолчанию, штатным генератором меню в качестве "горячей клавиши" назначается комбинация клавиши Alt и первого символа названия пункта меню. Как правило, это русская буква. В результате, генератор меню создает команду вида

DEFINE PAD _1h610hbkn OF _MSYSMENU PROMPT "Пример" COLOR SCHEME 3 ;  
  	KEY ALT+П, ""

Вот в момент выполнения подобной команды и возникает сообщение о синтаксической ошибке на фрагменте "KEY ALT+П". Игнорирование этой ошибки приводит к тому, что на данный пункт меню просто не назначается горячая клавиша. Хотя сам пункт меню успешно создается.

Решение

Решение заключается в том, чтобы для всех пунктов основной линейки меню принудительно назначать горячие клавиши. Например, русской букве "П" соответствует латинская буква "G" (одна и та же клавиша). Вот и следует назначить для PAD-пункта "Пример" горячую клавишу "Alt+G".

Правда, возможно и другое решение.

За генерацию меню отвечает специальная программа Genmenu.prg Ее можно отредактировать, для того, чтобы подавить автоматическую генерацию горячих клавиш, если они не были заданы явно. Для этого вызываете данную программу на редактирование:

MODIFY COMMAND (Home()+"genmenu.prg")

За добавление горячих клавиш отвечает функция AddKey. Перейдите к этой функции на команду

FUNCTION addkey

и закомментируйте в этой функции весь условный оператор, начинающийся с фразы:

IF !IsLeadByte(prompt)

Однако оставьте не закомментированной в нем единственную строчку

STORE "" to m.cKeyname

Т.е. соответствующий кусок программы должен выглядеть так:

*!* IF !IsLeadByte(prompt)   
 *!* STORE c_key_padhotkey_LOC + UPPER(LEFT(prompt,1)) TO m.cKeyname   
 *!* ELSE   
  STORE "" to m.cKeyname   
 *!* ENDIF

Сохраните и откомпилируйте измененный файл GenMenu.prg.

Все. Теперь Вам остается только повторить генерацию всех ранее созданных меню. Сообщение о синтаксической ошибке больше возникать не будут.

О других способах решения данной проблемы можно почитать здесь

Устранение сообщения о синтаксической ошибке при запуске меню

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как заполнить таблицу в MS Word

Вопрос
Как заполнить таблицу в документе MS Word данными из таблицы FoxPro?

Ответ

Прежде всего, следует серьезно обдумать возможность использования вместо прграммы MS Word для отображения табличных данных программы MS Excel. Поскольку именно эта программа предназначена для заполнения табличных данных. Для MS Word таблица – это вспомогательный элемент.

Впрочем, заполнение таблицы MS Word, в своей основе, мало отличается от заполнения таблицы в MS Excel. Точно также происходит адресация к конкретной ячейке с последующим изменением одного из свойств этой ячейки. Сложность заключается именно в способе адресации.

Адресацию к объектам MS Word можно сравнить с адресацией к объектам формы в FoxPro. Вы ведь можете положить объект TextBox как собственно на форму, так и на закладку PageFrame или внутрь объекта контейнера. Соответственно, изменится и способ адресации к объекту. Надо будет указать в иерархии все те объекты-контейнеры, внутри которых расположен нужный Вам объект.

Правда, MS Word имеет и другое отличие от объектов FoxPro. Как правило, Вы обращаетесь к объектам формы в FoxPro по их именам. Объекты MS Word, как правило, собственных имен не имеют. Все объекты MS Word являются членами тех или иных коллекций и обращение к ним происходит по их индексам внутри соответствующих коллекций.

Следовательно, в общем случае, адресация к таблице в MS Word будет иметь вид

Приложение_Word.Коллекция_Документов(Индекс_Документа).Коллекция_Таблиц(Индекс_Таблицы)

Но это только в том случае, если таблица лежит непосредственно на листе документа. Если же она вложена в другой объект, то между "Коллекцией_Документов" и "Коллекцией_Таблиц" необходимо добавить коллекцию объекта-контейнера.

Существенным недостатком такого способа адресации является невольная привязка к физическому порядку добавления объектов в документ MS Word. Например, если Вы добавили нужную Вам таблицу физически самой первой, то она, естественно, будет самой первой в коллекции таблиц. Но если Вы в процессе модификации шаблона документа вырежете Вашу таблицу, создадите новую таблицу, а потом восстановите старую таблицу, то она окажется уже второй в коллекции таблиц. Эту особенность следует помнить при написании программ заполнения таблиц в MS Word.

Сначала создадим шаблон, с которым и будем в дальнейшем работать.

Создайте новый документ MS Word. Лучше создавать не файл документа (расширение .Doc), а файл шаблона документа (расширение .Dot).

Теперь создайте в этом документе таблицу из 2 строк и любого количества столбцов. Это можно сделать, нажав иконку в виде таблицы. Если такой иконки нет, то выберите пункт меню "Таблица", подпункт "Нарисовать таблицу". Почему всего две строки? Сейчас объясню.

Первая строка будет строкой заголовка таблицы. Поставьте указатель курсора в любую ячейку первой строки таблицы, далее выберите пункт меню "Таблица", подпункт "Заголовки". Визуально ничего не изменилось. Однако если Вы снова выберете пункт меню "Таблица", то слева от подпункта "Заголовки" окажется "птичка". Т.е. текущая строка таблицы относится к заголовку таблицы.

Заголовок таблицы обладает тем свойством, что он автоматически копируется на новую страницу документа, если количество строк таблицы занимает больше, чем одну страницу. Собственно, можете сразу заполнить строку заголовка, т.к. вряд ли ее содержимое будет зависеть от данных в таблице FoxPro.

Итак, в результате, в документе появилась одна таблица из двух строк. Причем первая строка помечена как заголовок. Вторая строка предназначена для заполнения собственно данными.

Но ведь данных, скорее всего, будет больше, чем одна строка! Верно. Проблема только в том, что Вы заранее не знаете, сколько именно строк будет в таблице. Следовательно, придется формировать строки программно. В процессе заполнения таблицы.

Теперь, после всех этих предварительных подготовок, пишем собственно код в FoxPro.

  
 *Создаем новый документ MS WORD на базе ранее созданного шаблона  
  LOCAL loWord as Word.Application   
  loWord = CREATEOBJECT('Word.Application')  
    
 * Делаем созданный экземпляр приложения Word видимым  
 * В реальном проекте эта команда дается в самом конце,  
 * но здесь выносим ее в начало для отладки  
  m.loWord.Visible = .T.  
    
 * Создаем новый документ MS WORD на базе ранее созданного шаблона  
  LOCAL loDoc as Word.Document  
  loDoc = m.loWord.Documents.Add(fullpath('TestWord.dot'))  
    
 * Формируем ссылку на таблицу документа Word  
 * В данном случае нужная таблица - это физически самая первая таблица   
 * в коллекции таблиц, расположенной непосредственно на листе документа  
  LOCAL loTable as Word.Table   
  loTable = m.loDoc.Tables(1)  
    
 * Для заполнения таблицы Word создадим таблицу в FoxPro  
  CREATE Cursor Test (TestId I, TestName C(10))  
  INSERT INTO Test (TestId, TestName) VALUES (1, "Первая")  
  INSERT INTO Test (TestId, TestName) VALUES (2, "Вторая")  
  INSERT INTO Test (TestId, TestName) VALUES (3, "Третья")  
  INSERT INTO Test (TestId, TestName) VALUES (4, "Четвертая")  
  INSERT INTO Test (TestId, TestName) VALUES (5, "Пятая")  
    
 * Теперь собственно заполнение  
 * Счетчик, показывающий, какую строку таблицы Word сейчас заполняем  
  LOCAL lnWordRowNum  
 * Первая строка таблицы Word - это заголовок, поэтому начальное значение равно 2  
  lnWordRowNum = 2  
  select Test  
  SCAN  
 	* Сначала сравниваю общее количество строк в таблице со значением счетчика  
  	IF m.loTable.Rows.Count < m.lnWordRowNum  
 		* Если количество строк меньше, то создаю новую строку  
  		m.loTable.Rows.Add()  
  	ENDIF  
  	  
 	* И собственно заполнение  
  	m.loTable.Cell(m.lnWordRowNum,1).Range.Text = Test.TestId  
  	m.loTable.Cell(m.lnWordRowNum,2).Range.Text = Test.TestName  
  	  
 	* Увеличиваю значение счетчика заполняемой строки Word  
  	lnWordRowNum = m.lnWordRowNum + 1  
  ENDSCAN

В этом коде 'TestWord.dot' - это имя созданного Вами файла шаблона. Здесь имя приведено просто в качестве примера. Использована функция FullPath(), чтобы получить полный путь доступа к этому файлу.

Синтаксис вида

LOCAL loWord as Word.Application

Это нововведение версии Visual FoxPro 7.0 для подключения механизма IntelliSens. Если у Вас младшая версия FoxPro, то можете писать в привычном синтаксисе.

LOCAL loWord

Собственно на работоспособность программы это никак не влияет. Это всего-лишь облегчение процесса программирования, но это никак, никоим образом, не влияет на работоспособность программы.

Существенным остается вопрос, откуда я узнал все эти методы и свойства собственно приложения MS Word. По большей части из документации по языку Microsoft Visual Basic, встроенному в программу MS Word. Встроен как сам язык, так и документация .

Хотя, поиск существенно облегчил механизм IntelliSens в FoxPro. Я сразу вижу все свойства и методы того или иного объекта и предполагаю, что именно мне может понадобиться. Затем смотрю документацию по языку Microsoft Visual Basic и уточню, действительно ли это то, что мне надо.

Если количество строк в таблице MS Word всегда одно и то же, или же Вам надо заполнить определенные места в обычном текстовом документе, то для этого лучше воспользоваться рекомендациями, приведенными в другой статье:

Как мне вывести данные в существующий MS WORD документ

Описанный в данной статье механизм заполнения таблицы относительно медленный, хотя и самый надежный. Впрочем, как правило, таблицы, заполняемые в MS Word относительно небольшого размера, поэтому общее время заполнения таблицы будет не велико. Если же процесс заполнения таблицы MS Word станет занимать слишком много времени, то следует подумать о способах оптимизации этого процесса. Есть разные варианты, но здесь их описывать не имеет смысла.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как узнать какая команда Word или Excel выполняет нужное действие

Вопрос

Как узнать какая команда Word или Excel выполняет нужное действие.

Ответ

В программах Word и Excel существует режим автоматической записи всех действий пользователя данных программ. Поэтому достаточно просто включить этот режим, выполнить необходимое действие и посмотреть какая же именно команда отвечает за его выполнение.

Для этого выбирается пункт меню Excel с именем "Сервис" - "Макрос" - "Начать запись". В появившемся окне указываем имя макроса (по умолчанию "Макрос1") и нажимаем кнопку "Ok". В результате, поверх листа Excel появляется маленькое специфическое окошко - ToolBar - с именем "Остановить запись" и все Ваши действия будут автоматически записываться.

После того, как Вы выполните все необходимые действия, остановите запись макроса. Для этого просто нажмите иконку с черным квадратиком в этом ToolBar с именем "Остановить запись". Далее выберите пункт меню Excel с именем "Сервис" - "Макрос" - "Макросы". Выберите имя только что записанного макроса (по умолчанию "Макрос1") и нажмите кнопку "Изменить".

Откроется окно редактора Micosoft Visual Basic в котором будет отображен код Вашего макроса.

Правда, следует заметить, что "в чистом виде" использовать полученный код макроса в FoxPro нельзя. Необходимо его слегка "адаптировать". Как это сделать рассматривается в статье

Перевод макроса Excel в синтаксис FoxPro

Кроме того, следует понимать, что таким образом Вы сможете определить только те команды, которые можно визуализировать. Т.е. выполнение этих команд приводит к каким-либо изменениям на экране. Все прочие команды следует искать в справочном руководстве по диалекту языка Visual Basic соответствующего продукта.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как узнать значение константы Word или Excel

Вопрос

Как узнать значение константы Word или Excel?

Ответ

• Откройте Word или Excel, для которых Вы хотите узнать значение константы
• Выберите пункт главного меню "Сервис" - "Макрос" - "Редактор Visual Basic" (или по горячей клавише Alt+F11)
• В открывшемся окне выберите пункт главного меню "View" - "Object Browser" (или по горячей клавише F2)
• Далее в пустом окошке слева от кнопки с иконкой бинокля ввести имя искомой константы и нажать кнопку с иконкой бинокля (или клавишу Enter).

  В результате поиска в самом низу окна "Object Browser" будет отображено значение искомой константы.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как открыть файл в другом приложении

Вопрос

У меня есть файл, созданный в другом приложении (XLS, PDF, DOC и т.п.). Как мне из FoxPro открыть соответствующее приложение и открыть в нем этот файл.

Ответ

Для этой цели используется специальная API-функция ShellExecute

Declare Long ShellExecute in Shell32 ;   
  	Long 	hWnd, ;		&& хендл родительского окна  
  	String 	lpOperation, ;	&& что сделать с файлом "open", "print",  "explore"  
  	String 	lpFile, ;		&& имя файла. Можно с путем доступа  
  	String 	lpParameters, ;	&& используется только для исполняемых файлов  
  	String 	lpDirectory, ; 	&& директория, относительно которой надо искать файл  
  	Integer 	ShowCmd 	&& режим открытия приложения  
    
 * Это откроет Acrobat (если он есть)  
  mKod=ShellExecute(0, "open", "uidesign1.pdf", NULL, "C:\text", 1)   
    
 * Это отправит сразу на печать  
  mKod=ShellExecute(0, "print", "uidesign1.pdf", NULL, "C:\text", 1)   
    
 * Это откроет проводник Windows на указанной директории   
  mKod=ShellExecute(0, "explore", "C:\text", NULL, NULL, 1)

Если функция ShellExecute вернула значение больше 32, то команда выполнена успешно. В противном случае произошла какая-то ошибка.

Следует иметь в виду, что функция ShellExecute откроет только те файлы, расширение которых ассоциировано в операционной системе Windows с каким-либо приложением. Например, если на машине пользователя не установлен Acrobat, то и файлы с расширением pdf не смогут быть открыты. Просто нечем.

Также следует понимать, что Вы не можете из FoxPro получить доступ к приложению открытому через ShellExecute. Это приложение будет открыто как отдельный независимый от FoxPro процесс.

Если у вас стоит задача только открыть файл, то можно воспользоваться COM-интерфейсом Shell API следующим образом

  
  Local loShell  
  loShell = CreateObject('Shell.Application')  
  loShell.Open("C:\text\uidesign1.pdf")

Кроме того, использование COM-интерфейса вызовет стандартный диалог Windows с предложением выбрать приложение, если в системе Windows не зарегистрировано приложение ассоциированное с указанным расширением файла.

К сожалению, через COM-интерфейс Shell API невозможно отправить документ на печать. В этом случае придется воспользоваться напрямую API-функцией ShellExecute

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как мне вывести данные в существующий MS WORD документ

Вопрос
Как мне вывести данные в существующий MS WORD документ?

Ответ

Вариантов решения данной проблемы много. В данном случае будет рассмотрен вариант решения через предварительно созданный файл шаблона (файл с расширение DOT)

Сначала необходимо создать документ (шаблон) MS Word в который впоследствии будут вставлены нужные данные. Этот документ следует сохранить как шаблон MS Word.

В те места, где предполагается вставлять значения следует вставить специальные объекты, которые называются "Поля".

Эти объекты вставляются через пункт меню Word "Вставка", подпункт "Поле". При выборе данного пункта меню в появившейся форме следует выбрать поле с именем "Quote". Это поле относится к категории "Связи и ссылки". Введите в свойстве поля "Текст" какой-либо текст (он будет заменен при заполнении из FoxPro), установите, если надо, формат данных и нажмите кнопку "Ok".

Поле будет вставлено в документ MS Word, однако по умолчанию этот факт никак не отображается. Чтобы наглядно увидеть вставленный объект выделите весь текст, нажмите на выделенном тексте правой клавишей мыши и выберите пункт открывшегося меню "Коды/Значения полей".

То же самое можно сделать через общие настройки MS Word. Пункт главного меню "Сервис" - подпункт "Параметры" - Закладка "Вид" - Раздел "Показывать" - птичка "Коды полей".

Чтобы внести изменения в код поля выделите его, нажмите правую кнопку мыши и выберите пункт открывшегося меню "Изменить поле".

Повторите вставку "Поля" во все места, где Вы предполагаете впоследствии подставить собственные данные.

Если Вы хотите сделать вставку в таблицы в MS Word, то в ячейках этих таблиц вообще ничего не надо вставлять.

Все. С предварительной подготовкой закончили. Сохраните полученный документ как шаблон MS Word и закройте его.

Программное наполнение такого предварительно созданного шаблона будет выглядеть примерно так:

  
 * Создаем новый документ MS WORD на базе ранее созданного шаблона  
  LOCAL loWord, loDoc  
  loWord = CREATEOBJECT( 'WORD.APPLICATION')    
  loDoc=m.loWord.Documents.Add('Полный_путь_доступа'+'Имя_файла_шаблона.dot')  
    
 * Подставляем необходимые значения в поля   
  m.loDoc.Fields(число_порядковый_номер_поля).Result.text="Текст"  
    
 * Для заполнения данных таблиц WORD принцип такой  
  m.loDoc.Tables(число_порядковый_номер_таблицы).Cell(число_ряд,число_колонка).Range.Text="Текст"  
    
 * Делаем созданный документ видимым  
  m.loWord.Visible = .T.

Однако рассмотренный вариант имеет тот недостаток, что к созданным полям приходится обращаться по номерам. Это не всегда удобно. Было бы проще, если бы поля имели символьное обозначение. Поэтому, рассмотрим еще один вариант.

Также предварительно создаем файл шаблона, но в качестве вставляемых объектов будем использовать не "Поля", а "Поля формы". Для этого надо активизировать специальный ToolBar с именем "Формы" (Пункт главного меню "Вид" - "Панели инструментов" - "Формы").

Вставляем курсор на нужное место в шаблоне и нажимаем на панели инструментов "Формы" самую левую иконку с буквами "ab". В текущее место шаблона будет вставлен специальный объект "Поле формы".

Дважды щелкните левой клавишей мыши по "Полю формы" и откроется дополнительное окно свойств этого объекта. Сейчас нас интересует его свойство "Закладка". Это и будет то самое, символьное обозначение объекта, по которому к нему можно будет обратиться из программы.

Это обозначение (закладка) может быть любое. Единственное ограничение - оно должно быть уникально в пределах всего шаблона. Впрочем, за этим проследит сам Word.

Предположим, что Вы оставили закладку в значении по умолчанию "ТекстовоеПоле1". Тогда изменение его содержимого из программы будет иметь вид:

  
 * Создаем новый документ MS WORD на базе ранее созданного шаблона  
  LOCAL loWord, loDoc  
  loWord = CREATEOBJECT( 'WORD.APPLICATION')    
  loDoc=m.loWord.Documents.Add('Полный_путь_доступа'+'Имя_файла_шаблона.dot')  
    
 * Подставляем необходимые значения в поля   
  IF TYPE([m.loDoc.FormFields("ТекстовоеПоле1")])="O"  
  	m.loDoc.FormFields("ТекстовоеПоле1").Result="Новое значение"  
  ENDIF  
    
 * Делаем созданный документ видимым  
  m.loWord.Visible = .T.

К сожалению, такой синтаксис возможен только для Word 2000 или старше. Для младших версий Word придется по старинке обращаться через порядковый номер. Точнее, надо будет сканировать коллекцию FormFields на предмет поиска "Поля формы" со свойством Name = "ТекстовоеПоле1". Примерно так:

  
  LOCAL lnI  
  FOR lnI=1 TO m.loDoc.FormFields.Count  
  	IF m.loDoc.FormFields(m.lnI).Name == "ТекстовоеПоле1"  
  		m.loDoc.FormFields(m.lnI).Result="Новое значение"  
  	ENDIF  
  ENDFOR

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как получить разницу двух дат в формате: лет, месяцев, дней

Вопрос
Как получить разницу двух дат в формате: лет, месяцев, дней

Ответ

В общем случае, данный вопрос не имеет решения.

Пожалуйста, не надо сразу бросаться писать опровержения, что вот у меня есть готовый код, который это делает или вот есть ссылка на решение. Сначала дочитайте до конца, что именно подразумевается в данном случае под фразой "решения не имеет".

Проблема заключается в том, что нет однозначного определения того, что есть "месяц" и "год". Как правило, под этим подразумевают календарные месяцы. Но сложность в том, что календарный месяц - это понятие не абсолютное, а относительное. Календарный месяц - это не просто некоторое количество дней. Это количество дней, прошедших с определенной даты.

Для лучшего понимания проблемы рассмотрим простой пример.

Надо определить разницу дат между 30 января и 2 апреля одного 2008 года.

Если бы задача заключалась в определении количества дней, то все решалось бы простым вычитанием

?{^2008-04-02} - {^2008-01-30} && 63 дня

А как определить количество месяцев? Результат будет существенно зависеть от того, как именно будет определяться один месяц. Возможно несколько идеологий расчета:

Вариант 1

Прибавляем к начальной дате последовательно по одному месяцу до тех пор, пока результат не превысит конечной даты.

Под термином "месяц" в процессе прибавления подразумевается такая операция, в результате которой номер дня остается тот же самый, а номер месяца увеличивается на 1. Если у нового месяца нет такой даты, то устанавливается дата равная последнему дню нового месяца. Так работает функция GoMonth()

Это значит, что если прибавить один месяц к 30 января, то получим 29 февраля (2008 год - високосный), поскольку в феврале нет 30 числа.

Затем прибавляем к 29 февраля еще один месяц, получаем 29 марта. Прибавлять еще один месяц уже не надо, поскольку результат будет заведомо больше 2 апреля.

Между 29 марта и 2 апреля остается 4 дня. Значит, результат будет 2 месяца и 4 дня.

Заметьте, что в не високосном году результат был бы 2 месяца и 5 дней

Обратите внимание на тот факт, что если начальная дата равна 29, 30 или 31 января результат был бы один и тот же! Поскольку прибавление одного месяца давало бы все то же 29 февраля. Получается парадоксальная ситуация - количество дней разное, а результат одинаковый.

Вариант 2

Алгоритм похож на "Вариант 1", но прибавлять будем не по одному месяцу за раз, а сразу прибавим столько месяцев, чтобы оказаться как можно ближе к конечной дате. Т.е. прибавим к 30 января сразу 2 месяца и получим 30 марта.

Между 30 марта и 2 апреля остается 3 дня. Значит, результат будет 2 месяца и 3 дня.

Заметьте, что если бы конечным месяцем был бы не апрель, а март, то данный вариант расчета ничем не отличался бы от "Варианта 1".

Вариант 3

Под термином "месяц" будем понимать именно календарный месяц. Т.е. февраль - это интервал от 01 февраля до 29 февраля, март - это интервал от 01 марта до 31 марта.

В этом случае имеем 2 полных месяца - февраль и март. И "остатки" от граничных месяцев: 1 день до конца января и 2 дня апреля. Значит, результат будет 2 месяца и 3 дня.

Но в данном случае повезло. Оставшихся дней явно не хватает для полного месяца. А если бы оставшихся дней было бы, например, 40 (с 10 января по 20 апреля)? Встал бы вопрос, сколько дней надо выделить из этого количества дней, чтобы получить еще 1 месяц? Берем количество дней в январе (месяце начала периода) или в апреле (месяце конца периода)?

Вариант 4

Принимаем, что все месяцы имеют одинаковое количество дней, которое вычисляется по следующей формуле:

(365+365+365+366)/4/12 = 30.4375

Тогда количество месяцев - это просто отношение количества дней к данной константе, округленное до целого. Значит, результат будет 2 месяца и 2 дня.

Могут быть и другие варианты расчета.

Как видите, результат существенно зависит от того, что именно понимается под термином "месяц". Точнее, как именно этот самый месяц выделяется в заданном диапазоне. Причем, даже нельзя сказать, что один способ является "правильным", а другие "не правильные". Они все "правильные". Но в рамках определенной идеологии.

Другими словами, вопрос расчета интервала в формате "лет, месяцев, дней" заключается не столько в коде, сколько в идеологии (алгоритме) расчета. Как только будет принята определенная идеология расчета, запрограммировать ее не составит труда.

Выбор того или иного способа определения месяца, как правило, определяется той задачей, которую необходимо решить. Просто поздравить именинника (можно и несколько дней подряд - не страшно  ), определить трудовой стаж или статистика в родильном отделении.

Следует еще заметить, что те же проблемы касаются и определения любых других календарных интервалов. Таких как "неделя", "квартал", "год". Т.е. прежде чем писать код, необходимо описать по каким правилам будут определяться указанные интервалы.

Вы можете поискать уже готовые примеры расчета на данном сайте или в интернете. Но всегда следует иметь в виду, что все эти примеры кодируют определенную идеологию определения месяца и года. К сожалению, как именно (по какой идеологии) происходит это определение из кода далеко не всегда видно. Поэтому, результат работы найденных примеров может оказаться далек от ожидаемых Вами. Каждый пример следует тщательно протестировать для определения его пригодности под Вашу конкретную задачу.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как вывести приложение на передний план

Вопрос

Как вывести на передний план и активизировать окно нужного приложения. Это может быть окно Word, или ранее запущенное приложение FoxPro, или форма для ввода логина и пароля в приложении FoxPro (иногда она не выводится на передний план)

Ответ

Идея решения принадлежит Вадиму Пирожкову (piva)

Для вывода окна любого приложения на передний план, необходимо знать текст заголовка нужного окна.

  
  LOCAL loShell, lcCaption  
  loShell=CreateObject("WScript.Shell")      
  lcCaption = "Заголовок_нужного_Окна"  
  IF loShell.AppActivate(m.lcCaption) = .T.  
  	loShell.SendKeys("% ~")  
  ELSE  
  	MessageBox("Приложение "+m.lcCaption+" не найдено")  
  ENDIF

Метод loShell.AppActivate() выполняет поиск приложения по первым символам заголовка нужного окна и активизирует его, что сопровождается выводом окна на передний план. Если указанного окна обнаружить не удалось, то данный метод вернет .F., но никакого сообщения об ошибке не будет.

Проблема в том, что метод loShell.AppActivate() выводит приложение на передний план "как есть". Например, если приложение было свернуто (минимизировано), то оно, конечно, будет активизировано. Но активизировано в том же, свернутом, состоянии.

Чтобы приложение развернуть на весь экран необходимо выполнить некоторые манипуляции в самом приложении. Нажать некую последовательность клавиш. Вот именно этим и занимается метод loShell.SendKeys() - посылает в активное приложение некоторый набор кодов клавиш.

В данном случае набор посылаемых клавиш основан на том факте, что большинство приложений имеет системное меню, которое вызывается комбинацией клавиш "ALT+пробел". Это системное меню раскрывается также по нажатию клавиши мыши в левом верхнем углу приложения на иконке самого приложения.

Данное меню содержит пункты по управлению размером и положением окна. Причем самый первый пункт этого меню "Восстановить". Этот пункт (поскольку он первый) автоматически становится активным при открытии меню. Остается только нажать клавишу Enter для его выбора.

Вот именно эта последовательность клавиш - ALT+пробел+ENTER - и зашифрована в параметре метода

loShell.SendKeys("% ~")

Если Вы уверены, что активизируемое Вами приложение находится в "нормальном", развернутом состоянии, то вызывать метод loShell.SendKeys() нет необходимости.

Также вызывать именно эту последовательность нажатия клавиш не имеет смысла, если приложение не имеет стандартного системного меню. В FoxPro подавить активизацию системного меню можно, например, установив свойство

_SCREEN.ControlBox = .F.

Условное обозначение кодов клавиш, используемых в методе SendKeys(), приведено в следующей таблице

  
  Key 		Code   
  BACKSPACE 	{BACKSPACE}, {BS}, or {BKSP}   
  BREAK 		{BREAK}   
  CAPS LOCK 	{CAPSLOCK}   
  DEL or DELETE 	{DELETE} or {DEL}   
  DOWN ARROW 	{DOWN}   
  END 		{END}   
  ENTER 		{ENTER}or ~   
  ESC 		{ESC}   
  HELP 		{HELP}   
  HOME 		{HOME}   
  INS or INSERT 	{INSERT} or {INS}   
  LEFT ARROW 	{LEFT}   
  NUM LOCK 	{NUMLOCK}   
  PAGE DOWN 	{PGDN}   
  PAGE UP 	{PGUP}   
  PRINT SCREEN 	{PRTSC}   
  RIGHT ARROW 	{RIGHT}   
  SCROLL LOCK 	{SCROLLLOCK}   
  TAB 		{TAB}   
  UP ARROW 	{UP}   
  F1 		{F1}   
  F2 		{F2}   
  F3 		{F3}   
  F4 		{F4}   
  F5 		{F5}   
  F6 		{F6}   
  F7 		{F7}   
  F8 		{F8}   
  F9 		{F9}   
  F10 		{F10}   
  F11 		{F11}   
  F12 		{F12}   
    
  Key 		Code   
  SHIFT 		+   
  CTRL 		^   
  ALT 		%

Все прочие клавиши в методе SendKeys() выводятся как буквы соответствующих клавишь или их ASCII-коды в функции Chr(). Например, вместо символа "~" можно указать код chr(13) или {ENTER}

  
  loShell.SendKeys("% "+chr(13))  
 * или  
  loShell.SendKeys("% {ENTER}")

Как вывести на передний план текущее приложение FoxPro

В этом случае, заголовком приложения является значение свойства

_SCREEN.Caption

  
  LOCAL loShell  
  loShell=CreateObject("WScript.Shell")      
  loShell.AppActivate(_SCREEN.Caption)

В данном случае, как раз нет смысла использовать метод SendKeys() в силу того, что нужное Вам окно заведомо находится в нужном состоянии.

Как вывести на передний форму со свойством Form.ShowWindow = 2 - As Top-Level

Как правило, такие формы используются для ввода логина и пароля пользователя при открытии приложения. Однако, по умолчанию, на передний план выводится окно собственно среды FoxPro (_SCREEN), если до вызова формы была предпринята попытка активизировать основное окно FoxPro или сделать в него вывод какой-либо информации. Поэтому, зачастую, форма для ввода логина и пароля открывается, но на передний план не выводится.

В этом случае, в качестве заголовка окна используется заголовок формы.

  
 * Вызываю форму для ввода логина и пароля  
  DO FORM MyTopForm.scx    
    
 * Вывожу ее на передний план  
  LOCAL loShell  
  loShell=CreateObject("WScript.Shell")      
  loShell.AppActivate(MyTopForm.Caption)  
    
 * Организую точку останова приложения  
  READ EVENTS

В данном случае, как раз нет смысла использовать метод SendKeys() в силу того, что нужное Вам окно заведомо находится в нужном состоянии.

Как вывести на передний план приложение Word или Excel в котором сформировали отчет

Довольно распространенный способ формирования отчетов - это прямое заполнение документов в Word или Excel. Естественно, после формирования отчета хотелось бы вывести его на передний план.

Приложение Word

  
 * Создание экземпляра приложения Word  
  LOCAL loWord as Word.Application  
  loWord = CreateObject("Word.Application")  
 * Далее идет создание заполнение документа   
  ...  
 * Сформированный документ делается видимым  
  loWord.Visible = .T.  
    
 * Выводится экземпляр приложения Word на передний план  
  LOCAL loShell  
  loShell=CreateObject("WScript.Shell")      
  IF loShell.AppActivate(loWord.Caption) = .T.    
  	loShell.SendKeys("% ~")    
  ELSE    
  	MessageBox("Приложение "+loWord.Caption+" не найдено")    
  ENDIF

Приложение Excel

  
 * Создание экземпляра приложения Excel  
  LOCAL loExcel as Excel.Application  
  loExcel = CreateObject("Excel.Application")  
 * Далее идет создание и заполнение документа  
  ...  
 * Сформированный документ делается видимым  
  loExcel.Visible = .T.  
    
 * Выводится экземпляр приложения Excel на передний план  
  LOCAL loShell  
  loShell=CreateObject("WScript.Shell")      
  IF loShell.AppActivate(loExcel.Caption) = .T.    
  	loShell.SendKeys("% ~")    
  ELSE    
  	MessageBox("Приложение "+loExcel.Caption+" не найдено")    
  ENDIF

Однако в отношении Word или Excel есть специфический способ активизации, основанный на том, что разворачивание этого окна на максимум из свернутого (минимизированного) состояния автоматически приводит к его активизации.

Приложение Word

  
 * Выводится экземпляр приложения Word на передний план  
  #DEFINE wdWindowStateMinimize 2  
  #DEFINE wdWindowStateMaximize 1  
    
  loWord.WindowState = wdWindowStateMinimize	&& Сворачиваем окно  
  loWord.WindowState = wdWindowStateMaximize	&& Разворачиваем окно, что приводит к его активизации  

Приложение Excel

  
 * Выводится экземпляр приложения Excel на передний план  
  #DEFINE xlMinimized -4140  
  #DEFINE xlMaximized -4137  
    
  loExcel.WindowState = xlMinimized	&& Сворачиваем окно  
  loExcel.WindowState = xlMaximized	&& Разворачиваем окно, что приводит к его активизации  

В качестве констант для сворачивания и разворачивания Excel можно также использовать значения 1 и 2 из набора констант Word.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как работать с путями доступа и именами файлов, содержащих пробелы

Вопрос
При использовании путей доступа или имен файлов, содержащих пробелы, я получаю сообщения об ошибках. Как работать с путями доступа и именами файлов, содержащих пробелы?

Ответ

В общем случае следует обрамлять такие имена кавычками или использовать выражения имени.

Например, на Вашем компьютере есть файл по такому пути доступа:

Цитата:

C:\Мои документы\Мой файл.txt

Если Вы хотите обратиться к такому файлу напрямую, по имени, то это следует делать так:

MODIFY FILE "C:\Мои документы\Мой файл.txt"

Если Вы считали это имя в переменную памяти, например, при помощи функции GetFile() или имя директории при помощи функции GetDir(), то следует использовать выражение имени. Скобки.

  
  LOCAL lcFileName  
  lcFileName = GetFile()  
  MODIFY FILE (m.lcFileName)

В принципе, можно использовать и символ макроподстановки. Но в этом случае нужно достаточно хорошо понимать, что именно происходит в этом случае. Дело в том, что при использовании символа макроподстановки происходит формальная замена переменной памяти на тот текст, который в ней записан. Другими словами код

  
  LOCAL lcFileName  
  lcFileName = "C:\Мои документы\Мой файл.txt"  
  MODIFY FILE &lcFileName

фактически преобразуется в такой код

MODIFY FILE C:\Мои документы\Мой файл.txt

Далее вступает в действие синтаксический анализатор кода. Для него имя файла - это параметр команды. А параметры, в данном случае, отделяются друг от друга пробелами. Следовательно, FoxPro прочитает данную команду следующим образом:

MODIFY FILE C:\Мои

Разумеется, ни такой директории, ни имени файла не существует. И Вы получаете сообщение об ошибке.

Чтобы предотвратить подобное развитие событий, необходимо добавить дополнительные кавычки

  
  LOCAL lcFileName  
  lcFileName = ["C:\Мои документы\Мой файл.txt"]  
  MODIFY FILE &lcFileName

Этот код будет прочитан следующим образом

MODIFY FILE "C:\Мои документы\Мой файл.txt"

Вот здесь уже все в полном порядке. Параметр - это то, что ограничено кавычками.

Хотя, разумеется, использование дополнительных кавычек не слишком удобно. Поэтому проще при работе с именами файлов использовать выражения имени. Т.е. скобки. В этом случае Вы автоматически страхуетесь от возможных пробелов в именах файлов и путях доступа.

  
  LOCAL lcFileName  
  lcFileName = "C:\Мои документы\Мой файл.txt"  
  MODIFY FILE (m.lcFileName)

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Символьные поля, переменные памяти и константы

Вопрос

Я формирую запрос через SQLExec() или макроподстановку. Почему не получается сформировать запрос более чем на 255 символов?

Ответ

Символьные поля, переменные памяти и константы

В FoxPro существует отличия в предельно допустимой длине символьных данных в зависимости от того, о чем идет речь: поле таблицы, переменной памяти или константе

Ну, с полями таблицы все ясно. Их предельная длина определяется собственно размерностью поля. Однако размерность поля не может превышать 254 символов. Для memo-полей объем не может превышать 2ГБ (2 гигабайта - это 2 и 9 нулей символов).

Длина символьной константы не может превышать 255 символов

Длина символьной переменной теоретически не может превышать 16,777,184 символов. "Теоретически", потому, что при определенных условиях все-таки может. Просто за последствия такого превышения никто не отвечает.

Отдельно следует остановиться на отличии символьной константы от символьной переменной. Начинающие программисты очень часто получают сообщение об ошибке "Command contains unrecognized phrase/keyword (Error 36)" именно в силу непонимания этой разницы.

В FoxPro для написания символьных констант можно использовать 3 символа: одинарные кавычки, двойные кавычки, квадратные скобки. В чем отличие символьной константы от символьной переменной проще объяснить на примере. Словами получится долго и невнятно. Например:

  
  LOCAL lcString  
  lcString = 'Начало строки' + " середина строки " + [окончание строки]

Так вот, здесь то, что записано в кавычках и квадратных скобках - это 3 символьные константы, а lcString - это одна символьная переменная

Вообще-то, лично мне трудно представить, как можно написать одну символьную константу длиной больше 255 символов. Точнее написать-то такое можно, но как потом это можно редактировать! Получится совершенно не "читабельный" текст. Я рекомендовал бы разбивать длинные символьные константы на небольшие фрагменты с тем, чтобы каждый отдельный фрагмент целиком помещался в окне редактирования. Примерно так:

  
  LOCAL lcString  
  lcString = "Начало строки"+;  
        " середина строки "+;  
        "окончание строки"

В FoxPro нет специальных управляющих символов, как, например, в C используется обратный слеш. Поэтому, если Вам надо использовать кавычки не как границу символьной константы, а как собственно символ, то просто обрамляйте их кавычками другого типа:

?[ЗАО "Рога и копыта"]

Следует всегда помнить, что FoхPro отличается определенной "самостоятельностью" в преобразовании данных. Применительно к символьным данным это проявляется в том, что если Вы попытаетесь записать в символьное поле больше символов, чем позволяет его размерность, то ошибки это не вызовет, просто "лишние" символы будут отброшены без каких-либо дополнительных сообщений об ошибках.

  
  CREATE CURSOR test (test C(5))  
  INSERT INTO test (test) VALUES ("1234567890")  
  ?test.test

Если Вам надо записать в переменную памяти несколько строк текста "как есть", то, начиная с версии Visual FoxPro 7 для этой цели лучше использовать скобки TEXT...ENDTEXT

  
  LOCAL lcText  
    
  TEXT TO m.lcText NOSHOW  
  Первая строка текста  
  Вторая строка текста  
  "Название"  
  ENDTEXT  
    
  ?m.lcText

Как видите, все что находится между TEXT и ENDTEXT воспринимается не как набор команд, а просто как текст. Содержимое переменой m.lcText.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как работать с ini-файлами

Вопрос
Как работать (читать и записывать) с ini-файлами?

Ответ

ini-файл или файл с расширением из 3 букв "INI" (от слов initialization file - файл инициализации) - это обычный текстовый файл, который имеет специфическое содержание. Выглядит его содержимое примерно так:

// Комментарий
[Имя_раздела_1]
Имя_реквизита_1 = значение реквизита
Имя_реквизита_2 = значение реквизита

// Комментарий
[Имя_раздела_2]
Имя_реквизита_1 = значение реквизита
Имя_реквизита_2 = значение реквизита

Т.е. в квадратных скобках указывается имя раздела (другое название - "секция"), затем идет список реквизитов (другое название - "ключ") этого раздела и их значение. Количество разделов и количество реквизитов внутри раздела не ограничено.

Желательно давать имена разделам и реквизитам в одно слово из латинских букв без пробелов и спец.символов. Но это скорее перестраховка. Если для Вас удобнее воспринимать имя раздела или реквизита с пробелом (в два слова) - пишите с пробелом!

В качестве значения реквизита принимается вся строка от первого отличного от пробела символа после символа равенства до окончания строки, включая пробелы. Т.е. здесь для задания текстовой строки использовать кавычки не надо. Предполагается, что все значения имеют только и исключительно символьный тип.

Символом комментария обычно служит две наклонные черты подряд. Хотя, в принципе, можно использовать абсолютно любой символ (вот только пробел нельзя  ). Для используемых ниже API-функций важен факт совпадения искомого имени начиная с первого символа. Достаточно того, чтобы первый символ не совпадал с искомым.

В принципе, можно прочитать такой файл из FoxPro функциями чтения текстовых файлов (FOPEN(), FREAD(), FileToStr() и т.п.) и сделать его разбор. "Но есть способ лучше" (с). Существуют специальные API-функции предназначенные для чтения и записи INI-файлов.

GetPrivateProfileString - считывает значение указанного реквизита из указанного раздела.
WritePrivateProfileString - записывает значение указанного реквизита в указанный раздел указанного ini-файла. Если указанного раздела или реквизита не существует, то он будет создан. Если указанного ini-файла не существует, то он также будет создан.

Выглядит это примерно так:

Запись значения в ini-файл

  
  Declare Integer WritePrivateProfileString In Win32API As WritePrivStr ;    
  	String cSection, ;	&& имя раздела  
  	String cKey, ;	&& имя реквизита  
  	String cValue, ;	&& значение реквизита  
  	String posfile	&& имя ini-файла с полным путем доступа  
    
  LOCAL lnError  
  lnError = WritePrivStr("TestSection", ;  
  			"TestKey", ;  
  			"TestValue", ;  
  			Fullpath("test.ini"))  
  IF lnError<>1  
 	* Запись в ini-файл не удалась. Произошла ошибка  
  ELSE  
 	* Смотрим, что получилось во вновь созданном файле  
  	MODIFY FILE test.ini  
  ENDIF

Чтение значения из ini-файл

  
  Declare Integer GetPrivateProfileString In Win32API  As GetPrivStr ;    
  	String cSection, ;		&& Имя раздела  
  	String cKey, ;		&& Имя реквизита  
  	String cDefault, ;		&& Значение по умолчанию, если нет указанного раздела или реквизита  
  	String @cBuffer, ;		&& Собственно считанное значение реквизита  
  	Integer nBufferSize, ;	&& Максимальное количество символов в считанном реквизите  
  	String posfile		&& имя ini-файла с полным путем доступа  
    
  LOCAL lcBuffer, lnBuffer  
  lcBuffer = SPACE(2000)  
    
  lnBuffer = GetPrivStr("TestSection", ;  
  			"TestKey", ;  
  			"Нет значения", ;  
  			@lcBuffer, ;  
  			LEN(m.lcBuffer), ;  
  			Fullpath("test.ini"))  
    
  IF m.lnBuffer = 0  
 	* Ничего не прочитали  
  ELSE  
 	* Прочитанное значение храниться в первых m.lnBuffer символах переменной m.lcBuffer  
  	?LEFT(m.lcBuffer,m.lnBuffer)  
 	* Общая длина переменной m.lcBuffer по прежнему 2000 символов,   
 	* но символ m.lnBuffer+1 имеет ASCII-код равный 0, а все прочие - пробелы  
  ENDIF

Удаление раздела или реквизита
Удаление - это запись не определенного значения

  
 * Удаление только одного реквизита TestKey в разделе TestSection  
  LOCAL lnError  
  lnError = WritePrivStr("TestSection", ;  
  			"TestKey", ;  
  			NULL, ;  
  			Fullpath("test.ini"))  
  IF lnError<>1  
 	* Запись в ini-файл не удалась. Произошла ошибка  
  ELSE  
 	* Смотрим, что получилось   
  	MODIFY FILE test.ini  
  ENDIF  
    
 * Удаление всего раздела TestSection со всеми реквизитами  
  LOCAL lnError  
  lnError = WritePrivStr("TestSection", ;  
  			NULL, ;  
  			NULL, ;  
  			Fullpath("test.ini"))  
  IF lnError<>1  
 	* Запись в ini-файл не удалась. Произошла ошибка  
  ELSE  
 	* Смотрим, что получилось   
  	MODIFY FILE test.ini  
  ENDIF

Определение структуры ini-файла

Если структура ini-файла, т.е. имена секций и ключей, заранее не известны, то получить структуру ini-файла можно также используя функцию GetPrivateProfileString указав вместо имени секции или ключа число 0.

В этом случае в качестве возвращаемого значения Вы получите либо список имен секций (если указать 0 первым параметром), либо список имен ключей указанной секции (если указать 0 вторым параметром). Имена будут разделены символом Chr(0)

  
 * Список секций ini-файла  
  LOCAL lcBuffer, lnBuffer  
  lcBuffer = SPACE(2000)  
    
  lnBuffer = GetPrivStr(0, ;  
  			0, ;  
  			"", ;  
  			@lcBuffer, ;  
  			LEN(m.lcBuffer), ;  
  			Fullpath("test.ini"))  
    
  IF m.lnBuffer > 0  
  	m.lcBuffer = CHR(0) + LEFT(m.lcBuffer,m.lnBuffer)  
  	LOCAL lnI, lnFromPos, lnToPos  
  	FOR m.lnI = 1 TO OCCURS(CHR(0),m.lcBuffer)-1  
  		lnFromPos = AT(CHR(0),m.lcBuffer,m.lnI)  
  		lnToPos = AT(CHR(0),m.lcBuffer,m.lnI+1)  
  		?SubStr(m.lcBuffer,m.lnFromPos+1,m.lnToPos-m.lnFromPos-1)  
  	ENDFOR  
  ENDIF  
    
 * Аналогично получаем список ключей секции TestSection   
  LOCAL lcBuffer, lnBuffer  
  lcBuffer = SPACE(2000)  
    
  lnBuffer = GetPrivStr("TestSection", ;  
  			0, ;  
  			"", ;  
  			@lcBuffer, ;  
  			LEN(m.lcBuffer), ;  
  			Fullpath("test.ini"))  
    
  IF m.lnBuffer > 0  
  	m.lcBuffer = CHR(0) + LEFT(m.lcBuffer,m.lnBuffer)  
  	LOCAL lnI, lnFromPos, lnToPos  
  	FOR m.lnI = 1 TO OCCURS(CHR(0),m.lcBuffer)-1  
  		lnFromPos = AT(CHR(0),m.lcBuffer,m.lnI)  
  		lnToPos = AT(CHR(0),m.lcBuffer,m.lnI+1)  
  		?SubStr(m.lcBuffer,m.lnFromPos+1,m.lnToPos-m.lnFromPos-1)  
  	ENDFOR  
  ENDIF

Разумеется, объявлять API-функции каждый раз перед записью или чтением значений нет необходимости. Достаточно объявить эти функции один раз в стартовом файле.

Также пример работы с INI-файлами можно посмотреть в классе, поставляемом вместе с FoxPro

MODIFY CLASS oldinireg OF HOME()+'FFC\registry.vcx'

Хотя в новейшей идеологии Microsoft предполагается, что вместо ini-файлов следует использовать запись/чтение в системный реестр Windows.

Применительно к FoxPro следует рассмотреть возможность хранения дополнительных настроек в обычном файле DBF, поскольку FoxPro предназначен, прежде всего, именно для работы с файлами DBF.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как проверить факт существования переменной памяти, поля таблицы, метода формы

Вопрос
Как проверить факт существования переменной памяти, поля таблицы, метода формы и т.п. ?

Ответ

В большинстве случаев такая проверка может быть осуществлена с помощью функции TYPE(). В качестве вычисляемого значения в эту функцию передается тот объект, факт существования которого проверяем. Если в результате получаем значение отличное от "U", то это означает, что такой объект существует.

Как проверить факт существования переменной памяти

IF TYPE("m.MyVar") = "U"  
 	* Переменной памяти с именем MyVar - не существует  
  ENDIF

Как проверить факт существования поля таблицы (курсора, View)

Если таблица (курсор, View) уже открыта в текущей DataSession, то

IF TYPE("MyTableAlias.MyField") = "U"  
 	* Для таблицы, открытой с алиасом MyTableAlias   
 	* не существует поля с именем MyField  
  ENDIF

Если таблица включена в контейнер базы данных, то открывать саму таблицу (View) не обязательно. Проверить факт существования нужного поля можно так:

IF InDBC("MyTable.MyField","FIELD") = .F.  
 	* Для таблицы, включенной в контейнер базы данных под именем MyTable   
 	* не существует поля с именем MyField  
  ENDIF

Как проверить факт существования (использования, открытия) формы

IF TYPE("_VFP.Forms('MyForm')")="U"  
 	* Формы со свойством name = MyForm не существует (не открыта)  
  ENDIF

Обратите внимание, что здесь используется системная переменная _VFP. Использовать аналогичный синтаксис с системной переменной _SCREEN - не получиться. Коллекция _SCREEN.Forms() не принимает в качестве параметра символьные значения. Только числовые.

Кроме того, данный способ не сработает для форм, имеющих значение совйства ShowWindow = 2 - As Top-Level Form. В этом случае придется просто перебирать весь массив _SCREEN.Forms() или _VFP.Forms()

LOCAL lnI, loForm  
  loForm = NULL  
  FOR lnI=1 TO _SCREEN.FormCount  
  	loForm = _SCREEN.Forms(m.lnI)  
  	IF m.loForm.Name = "MyForm"  
 		* Нашли форму со свойством Name = "MyForm"  
  		EXIT  
  	ENDIF  
  	loForm = NULL  
  ENDFOR  
  IF IsNull(m.loForm) = .T.  
 	* Формы со свойством name = MyForm не существует (не открыта)  
  ENDIF

Как проверить факт существования метода, события или свойства в используемом объекте

IF TYPE("_VFP.Forms('MyForm')")="O" AND PEMStatus(_VFP.Forms('MyForm'),'MyMethod',5) = .T.  
 	* Открыта форма со свойством name = MyForm   
 	* и в этой форме существует метод, событие или свойство с именем MyMethod  
  ENDIF

Для форм, со свойством ShowWindow = 2 - As Top-Level Form данный способ не годится. Придется также перебирать все элементы массива _SCREEN.Forms() как и в предыдущем примере.

Замечание

Кроме приведенных способов есть и другие варианты проверки факта существования того или иного объекта. Причем от версии к версии количество способов растет, поскольку появляются все новые команды и функции.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как определить директорию, из которой запущена программа

Вопрос
Как определить директорию, из которой запущена готовая программа (файл EXE)

Ответ

В общем случае, этого сделать невозможно! Есть масса способов "сбить с толку" любые команды и функции.

Однако все-таки есть ряд функций, которые могут решить подобную проблему при определенных условиях. Надо всегда помнить, что эти функции не абсолютны. Имеют ограничения.

  
 * Путь доступа к первой запущенной программе (главному файлу проекта)  
  JustPath(SYS(16,0))  
    
 * Путь доступа к текущей директории  
  FullPath("") - пустая строка (две кавычки подряд) - обязательны  
  SYS(5)+SYS(2003)  
  SET("DEFAULT")+CURDIR()  
  _VFP.DefaultFilePath

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как восстановить поврежденную таблицу

Вопрос

Таблица нормально открывалась. Однако после сбоя питания (не корректного выключения компьютера) при открытии таблицы возникает сообщение об ошибке

Цитата:

"file" is not a table (Error 15)

Как можно починить таблицу?

Причина

Файл DBF можно рассматривать как обычный текстовый файл. Просто текст. Но такой текст, который имеет определенную внутреннюю структуру. Т.е. любая информация всегда находится по определенному "адресу". В определенном месте этого файла. Грубо говоря, в файле DBF значение вот этого поля из вот этой строки должно находится вот в этом месте.

Что и где должно находится, так сказать, "оглавление", записывается в самом начале файла. В так называемой "заголовочной части". Это просто самое начало файла. После которого идет само содержание файла. Данные.

Естественно "оглавление" должно соответствовать определенному "стандарту", зависящему от версии FoxPro, а также должно соответствовать "содержанию". И некоторые из таких соответствий можно проверить. Т.е. посмотреть действительно ли в указанном месте находится соответствующие данные? Что, собственно, и делает FoxPro при открытии файлов DBF.

Чем старше версия FoxPro, тем большее количество параметров проверяется при открытии файла DBF. Если какой-то параметр не соответствует тем значениям, которые должны быть, то FoxPro выдает сообщение об ошибке

Решение

Прежде чем попытаться "исправить" файл DBF, не важно, каким способом, желательно сделать резервную копию. Пусть и поврежденного файла. Как бы "лечение" не сделало хуже!

Помните, что таблица - это совокупность трех файлов с одинковым именем и с расширениями

DBF - собственно таблица
FPT - содержимое мемо-полей
CDX - структурный индексный файл

Это значит, что делать резервную копию надо всех трех файлов. Разумеется, если они есть.

Теоретически, можно самостоятельно проверить соответствие структуры таблицы ее реальному содержанию. В Help по FoxPro достаточно подробно описана структура таблицы и ее заголовочной части. Оглавления. Это статья с названием

Table File Structure (.dbc, .dbf, .frx, .lbx, .mnx, .pjx, .scx, .vcx)

А для мемо-полей, которые хранятся в отдельном файле с расширением FPT это статья с названием

Memo File Structure (.FPT)

Для проверки можно открыть таблицу любым низкоуровневым текстовым редактором. Например, Norton Commander, Disco Commander, FAR-manager и т.п. Далее проанализировать значения в заголовочной части и в области с данными.

Проблема только в том, что при больших размерах файла такой анализ может занять очень много времени. А ручное исправление ошибок очень утомительный процесс.

Тем не менее, просмотреть поврежденный файл в низкоуровневом редакторе бывает полезно. Как правило, при этом можно сделать некоторые общие выводы. Например, а есть ли в файле вообще какая-либо информация. Не заполнен ли файл каким-либо "мусором".

Если стоит задача "спасти" информацию текстового содержания из мемо-полей, то ее можно просто скопировать из файла FPT, поскольку она хранится в нем "как есть". Да и информацию из полей таблицы можно прочитать напрямую. Правда, не всегда "как есть". Иногда требуются некоторые преобразования.

-------------------------------------------------------------------------------------

Есть некоторые способы, позволяющие в простых случаях "привести в чувство" испорченную таблицу.

Если таблицу все-таки удалось открыть, например, отключив проверку структуры настройкой

SET TABLEVALIDATE TO 0

Или же открыв таблицу в младшей версии Visual FoxPro. То можно попробовать выполнить следующие действия:

1. При помощи команды COPY TO скопировать содержимое таблицы в другой файл. Команда COPY TO создаст таблицу корректной структуры.
2. Очистить содержимое испорченной таблицы при помощи команды ZAP или просто пересоздать таблицу заново, если ничто не помогает
3. Заполнить пустую таблицу командой APPEND FROM данными, сохраненными ранее в копии, при помощи команды COPY TO.

Иногда, помогает использование команды PACK.

Если повреждения коснулись ссылок на мемо-поля, то иногда помогает создание нового мемо-поля с последующим его удалением. Дело в том, что факт создания нового мемо-поля заново обновляет все ссылки. Хотя, скорее всего, это приведет к потере данных, записанных в мемо-полях. Но их можно будет достать напрямую, открыв файл FPT как текстовый файл.

--------------------------------------------------------------------------------

Одна из самых распространенных ошибок - это рассогласование реального количества записей и того значения, которое записано в "оглавлении". Среда FoxPro считает, что в таблице находится столько записей, сколько указано в "оглавлении" этой таблицы.

Если в старших версиях FoxPro это рассогласование вызовет сообщение об ошибке в момент открытия, то в младших версиях FoxPro это соответствие не проверяется. Как следствие, при открытии таблицы Вы увидите меньше записей, чем есть на самом деле. Или больше. Но в последнем случае, эти "лишние" записи будут заполнены "мусором".

Собственно, довольно просто проверить это соответствие самостоятельно. Достаточно посмотреть, как именно формируется "оглавление" в файле DBF. Т.е. посмотреть в HELP структуру файла DBF. Или поискать в интернете различные "фиксеры", которые исправляют некоторые повреждения структуры файла DBF.

Только следует с осторожностью использовать "фиксеры" найденные в интернете. Учитывая тот факт, что есть отличия в структурах файлов DBF для FoxPro 2.x и Visual FoxPro. Отличия в структуре файлов DBF разных версий Visual FoxPro можно считать не существенным с точки зрения исправления возможных повреждений структуры. Впрочем, и большинство "фиксеров" разработанных для FoxPro 2.x могут успешно исправить и повреждение таблиц Visual FoxPro.

Еще раз напомню, прежде чем попытаться "исправить" файл DBF при помощи сторонней утилиты, желательно сделать резервную копию. Пусть и поврежденного файла. Как бы "лечение" не сделало хуже!

-------------------------------------------------------------------------

Ниже приведен один из вариантов исправления

  
 *********************************************************************  
 * Назначение : 	Приведение в соответствие значение количества записей   
 *		в заголовке таблице и реального количества записей  
 * Автор : 	Владимир Максимов  
 * Дата : 	31.08.2008  
 * Версия FoxPro: Visual FoxPro с 3 по 9  
 *		Возможно, этот код будет работать и в версиях FoxPro 2.x  
 *		если убрать объявления LOCAL и MessageBox()   
 *		Но это не проверялось  
 *********************************************************************  
    
 * Пользователь выбирает файл для проверки  
 * 5 параметр в функции GetFile() был введен только в версии Visual FoxPro 6  
 * для младших версий FoxPro его надо удалить  
  Local lcFileName  
  lcFileName = GetFile("DBF","","",0,"Выбор файла для проверки количества записей")  
  If Empty(m.lcFileName)  
 	* Файл не был выбран  
  	Return  
  EndIf  
    
 * Открываю файл и запоминаю его дескриптор (идентификатор)  
  Local lnFD  
  lnFD = Fopen(m.lcFileName,12)  
  If m.lnFD < 0  
  	MessageBox("Не удалось открыть файл" + Chr(13) + ;  
  		m.lcFileName + Chr(13) + ;  
  		"Возможно, он открыт другим приложением")  
  EndIf  
    
 * Теоретически, здесь хорошо бы добавить проверку на тот факт,   
 * что данный файл - это DBF-таблица (анализ первого байта)  
 * Но в данном случае предполагается, что пользователь понимает, что он делает  
 * Если, тем не менее, Вы хотите создать универсальную утилиту, то  
 * посмотрите код программы CPZERO.PRG из поставки FoxPro.  
 * Эта программа находится в каталоге TOOLS\CPZERO корневой папки FoxPro  
    
 * Определяю количество записей записанное в заголовке файла  
 * байты с 4 по 7  
  LOCAL lnReccount  
  =FSEEK(m.lnFD,4)  
  lnReccount =	ASC(FREAD(m.lnFD,1)) + ;  
  		ASC(FREAD(m.lnFD,1)) * 256 + ;  
  		ASC(FREAD(m.lnFD,1)) * 256 * 256 + ;  
  		ASC(FREAD(m.lnFD,1)) * 256 * 256 * 256  
  			  
 * Определяю позицию, с которой начинается собственно данные (первая запись)  
 * байты с 8 по 9  
  LOCAL lnDataStart  
  lnDataStart = 	ASC(FREAD(m.lnFD,1)) + ;  
  		ASC(FREAD(m.lnFD,1)) * 256  
    
 * Определяю количество символов в одной записи, включая метку на удаление  
 * байты с 10 по 11  
  LOCAL lnRecLength  
  lnRecLength =	ASC(FREAD(m.lnFD,1)) + ;  
  		ASC(FREAD(m.lnFD,1)) * 256  
    
 * Определяю общий размер файла, через порядковый номер последнего байта  
  LOCAL lnFileSize  
  =FSEEK(m.lnFD,0,0)  
  lnFileSize = FSEEK(m.lnFD,0,2)  
    
 * Определяю значение самого последнего байта файла  
  LOCAL lnEndByte  
  =FSEEK(m.lnFD,-1,1)  
  lnEndByte = ASC(FREAD(m.lnFD,1))  
    
 * И реальное количество записей в файле  
  LOCAL lnFaktCount  
  DO CASE  
  CASE m.lnFileSize = m.lnDataStart  
 	* Т.е. в таблице вообще нет информации  
  	lnFaktCount = 0  
  CASE m.lnEndByte = 26  
 	* Если последний байт файла имеет ASCII код 26 (0x1A),   
 	* то общее число информационных байтов надо уменьшить на 1  
  	lnFaktCount = (m.lnFileSize - m.lnDataStart - 1) / m.lnRecLength  
  OTHERWISE  
  	lnFaktCount = (m.lnFileSize - m.lnDataStart) / m.lnRecLength  
  ENDCASE  
    
    
  LOCAL lnResult  
 * Анализ полученных результатов  
  DO CASE  
  CASE INT(m.lnFaktCount) <> m.lnFaktCount  
    
 	* Есть дробная часть. Т.е. выделить целое количество записей невозможно  
 	* повреждения более существенные, чем разница в количестве записей  
 	* лучше ничего не трогать  
  	lnResult = -1  
  	=Fclose(m.lnFD)  
  	  
  	MessageBox("Выделить целое количество записей невозможно"+Chr(13) + ;  
  				"Повреждения более существенные, чем разница в количестве записей")  
    
  CASE m.lnFaktCount <> m.lnReccount  
    
 	* Записанное и фактическое количество записей отличаются  
 	* корректирую записанное количество записей  
  	=FSEEK(m.lnFD,4,0)  
  	FOR lnI=1 TO 4  
  		=FWRITE(m.lnFD,CHR(MOD(INT(m.lnFaktCount / 256**(m.lnI-1)),256)))  
  	ENDFOR  
    
  	lnResult = 1  
  	=Fclose(m.lnFD)  
    
  	MessageBox("Значение количества записей исправлено")  
    
  OTHERWISE  
    
 	* Ошибки в определении количества записей не обнаружено  
  	lnResult=0  
  	=Fclose(m.lnFD)  
    
  	MessageBox("Ошибки в количестве записей не обнаружено")  
    
  ENDCASE  
    
 * Результат возвращается на случай, если есть необходимость в подобном анализе  
  RETURN m.lnResult

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как получить программный код создания структуры базы данных

Вопрос
Как я могу получить (посмотреть) программный код создания структуры базы данных

Ответ

Вместе с FoxPro поставляется утилита (программа) по генерации программного кода структуры существующей базы данных. Она называется GenDBC.prg

В командном окне FoxPro дайте команду

DO (HOME()+"Tools\GenDBC\GenDBC.prg")

Скобки в данном случае обязательны

Сначала Вам будет предложено указать контейнер базы данных (файл DBC), структуру которого Вы хотите получить.

Следующим шагом Вас попросят указать имя файла PRG, куда будет записана полученная структура.

В результате работы данной утилиты, Вы получите файл PRG, который можно просмотреть из среды FoxPro через стандартную команду

MODIFY COMMAND

Запуск данного файла на исполнение создаст структуру базы данных полностью идентичную тому контейнеру базы данных, который был использован в качестве образца. Разумеется, пустую. Без самих данных.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

При работе в сети иногда не открывается таблица

Проблема

В сетевом приложении при одновременной работе нескольких пользователей иногда не открываются таблицы. Возникает сообщение вроде  "Attempting to lock... Press Esc to cancel"

Причина

Это связано с ужесточением контроля структуры таблиц в момент их открытия, начиная с версии Visual FoxPro 8. Варианты этого контроля регулируются настройкой

SET TABLEVALIDATE

На момент проведения такого контроля (при открытии таблицы) требуется заблокировать заголовок таблицы. Если это невозможно (заголовок блокирован другим пользователем), то и возникает данное сообщение.

Решение

В принципе, Вы, конечно, можете снизить уровень контроля, изменив настройку SET TABLEVALIDATE. Однако более корректным является изменение самой логики построения многопользовательского приложения.

Основная идея изменения логики заключается в уменьшении времени блокировки как заголовка таблицы (что необходимо в данном случае), так и каких-либо блокировок в таблицах вообще. Т.е. недопустимо давать команду типа FLOCK() на неопределенно долгое время, ожидая реакции пользователя. Или использовать пессимистическую буферизацию.

Блокировка должна осуществляться только в момент сохранения внесенных изменений и в этот момент недопустимо ожидание реакции пользователя.

Разумеется, такая идеология построения многопользовательского приложения при неизменном уровне контроля SET TABLEVALIDATE не устранит данную проблему совсем, но существенно снизит как вероятность ее появления, так и вероятность повреждения таблиц в случае аварийного отключения питания.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Запрос с GROUP BY выдает сообщение о синтаксической ошибке

Проблема

Я выполняю примерно такой запрос

SELECT company, country FROM Customer GROUP BY country

И в версии FoxPro начиная с 8 и выше, получаю сообщение вроде

Цитата:

SQL: GROUP BY clause is invalid (Error 1807)

Причем в младших версиях FoxPro подобный запрос работал без проблем.

Причина

Начиная с версии Visual FoxPro 7.0, были ужесточены требования к корректности конструкции SQL-запросов.

В данном случае запрос содержит неоднозначность: Какое именно значение поля company надо взять из таблицы, если для одного и того же значения country их может существовать несколько?

В младших версиях FoxPro в этом случае использовалось первое попавшееся значение. В старших версиях FoxPro такая конструкция воспринимается как синтаксически некорректная.

Решение

Следует перечислить в конструкции GROUP BY все поля результирующей выборки, которые не имеют агрегирующих функций

SELECT company, country FROM Customer GROUP BY company, country

или добавить любую агрегирующую функцию к тем полям, которые не перечислены в конструкции GROUP BY

SELECT MAX(company) as company, country FROM Customer GROUP BY country

Впрочем, если Вы переводите свое приложение со старой версии FoxPro в новую версию, то можно явно указать FoxPro, что нужно использовать старые правила разбора и выполнения SQL-запроса при помощи настройки

SET ENGINEBEHAVIOR 70

Однако, по возможности, все-таки лучше придерживаться стандартных правил составления запросов в том смысле, что в конструкции GROUP BY должны быть перечислены все поля, которые не участвуют в агрегирующих функциях.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как изменить значения в одной таблице данными из другой

Задача

Есть две таблицы связанные отношением один-к-одному по содержимому ключевых полей. Как можно изменить значения в поле главной таблицы на значение поля подчиненной таблицы из соответствующей записи?

Решение

Исходные данные

  
 * Главная таблица    
  CREATE CURSOR tabMain (tabMainID I, Summa N(18,2))  
  INDEX ON tabMainID TAG tabMainID  
  SET ORDER TO 0  
  INSERT INTO tabMain (tabMainID, Summa) VALUES (1, 0)  
  INSERT INTO tabMain (tabMainID, Summa) VALUES (2, 0)  
  INSERT INTO tabMain (tabMainID, Summa) VALUES (3, 0)  
    
 * Подчиненная таблица    
  CREATE CURSOR tabChild (tabChildID I, tabMainID I, Qty I, Price N(18,2))  
  INDEX ON tabMainID TAG tabMainID  
  SET ORDER TO 0  
  INSERT INTO tabChild (tabChildID, tabMainID, Qty, Price) VALUES (1, 1, 10, 0.25)  
  INSERT INTO tabChild (tabChildID, tabMainID, Qty, Price) VALUES (2, 2, 15, 10.05)  
  INSERT INTO tabChild (tabChildID, tabMainID, Qty, Price) VALUES (3, 3, 30, 5.00)

Способ решения отличается для версии Visual FoxPro 9 и младших версий, поскольку в 9 версии значительно расширены возможности команды Select-SQL

  
 * Для версии младше Visual FoxPro 9  
  SELECT tabMain  
  REPLACE FOR SEEK(tabMain.tabMainID,"tabChild","tabMainID") ;  
  	Summa WITH tabChild.Qty*tabChild.Price  
    
 * Или через команду UPDATE  
  UPDATE tabMain SET Summa = tabChild.Qty*tabChild.Price ;  
  	WHERE SEEK(tabMain.tabMainID,"tabChild","tabMainID")   
    
 * Для Visual FoxPro 9  
  UPDATE tabMain ;  
  SET Summa =tabChild.Qty*tabChild.Price ;  
  FROM tabChild ;  
  WHERE tabMain.tabMainID=tabChild.tabMainID

Если дочерняя таблица не имеет нужного индекса, то для версии младше Visual FoxPro 9 остается только сканирование главной таблицы с поиском нужной записи в подчиненной таблице через команду LOCATE

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как выполнить восстановление поврежденных индексов

Вопрос

Как выполнить восстановление поврежденных индексов

Ответ

В версии FoxPro 2.x стандартным советом было: удалите все индексы и создайте их заново.

Однако с появление контейнера базы данных в Visual FoxPro последовать данному совету крайне затруднительно. Проблема в том, что кроме собственно создания файлов CDX потребуется еще восстановить ряд реквизитов внутри контейнера базы данных. В принципе, можно сделать и это. Но есть более простой способ.

1. Предварительно Вам необходимо создать резервную копию структуры Вашей базы данных. Т.е. вообще все файлы DBF, CDX, FPT, DBC, DCT, DCX, но без собственно данных. Пустые таблицы. В данном случае также подойдет резервная копия Вашей базы данных. Т.е. заполненные данные за предыдущий период. Главное, чтобы эта копия имела не поврежденные индексные файлы.
2. В случае повреждения индексов, все файлы CDX просто удаляются из рабочей базы данных. На их место копируются одноименные файлы из резервной копии.
3. Поскольку структура файлов CDX в резервной копии не повреждена, то Вы сможете открыть Ваши таблицы в эксклюзивном (единоличном) режиме без проблем. Т.е. без сообщений об ошибках.

   USE MyTab.dbf EXCLUSIVE

4. Теперь остается только привести в соответствие содержимое индексных файлов и собственно таблиц. Для этого следует использовать команду

   REINDEX

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Выбрать записи с повторяющимися (дублирующими) значениями поля

Задача

Есть одна таблица. В одном из ее полей могут содержаться повторяющиеся значения. Т.е. разные записи этой таблицы могут иметь одно и то же значение в этом поле. Как выбрать все записи, в которых имеются повторяющиеся (дублирующие) значения в этом поле.

Решение

  
 * Исходная таблица    
  CREATE CURSOR tabMain (tabMainID I, NickName C(50), curDate D, Chet L)  
  INSERT INTO tabMain (tabMainID, NickName, curDate, Chet) VALUES (1, "Первая запись", Date(2005,6,1), .F.)  
  INSERT INTO tabMain (tabMainID, NickName, curDate, Chet) VALUES (2, "Вторая запись", Date(2005,6,2), .T.)  
  INSERT INTO tabMain (tabMainID, NickName, curDate, Chet) VALUES (3, "Третья запись", Date(2005,6,3), .F.)  
  INSERT INTO tabMain (tabMainID, NickName, curDate, Chet) VALUES (4, "Четвертая запись", Date(2005,6,1), .T.)  
  INSERT INTO tabMain (tabMainID, NickName, curDate, Chet) VALUES (5, "Пятая запись", Date(2005,6,2), .F.)  
  INSERT INTO tabMain (tabMainID, NickName, curDate, Chet) VALUES (6, "Шестая запись", Date(2005,6,1), .T.)

У функции DATE() можно задавать параметры, начиная с версии Visual FoxPro 6. Для младших версий укажите значение даты другим способом.

Находим все записи, у которых повторяется значение поля curDate

  
  SELECT DISTINCT tabMain.* ;    
  FROM tabMain ;    
  INNER JOIN tabMain tabDouble ON tabMain.curDate = tabDouble.curDate  ;    
    			AND tabMain.tabMainID <> tabDouble.tabMainID ;  
  ORDER BY tabMain.curDate

Следует иметь в виду, что данное решение опирается на тот факт, что у таблицы есть уникальное (не повторяющееся) ключевое поле tabMainID.

Кроме того, данное решение легко расширить для случая, если требуется отобрать записи по повторяющемуся значению в нескольких полях. Достаточно просто добавить дополнительное условие через AND в условие объединения таблицы.

Например, найти все записи, у которых повторяется как значение поля curDate, так и значение поля Chet.

  
  SELECT DISTINCT tabMain.* ;    
  FROM tabMain ;    
  INNER JOIN tabMain tabDouble ON tabMain.curDate = tabDouble.curDate  ;    
    			AND tabMain.Chet = tabDouble.Chet ;  
    			AND tabMain.tabMainID <> tabDouble.tabMainID ;  
  ORDER BY tabMain.curDate, tabMain.Chet

Если у Вас стоит более простая задача: определить просто список значений, которые встречаются в таблице более одного раза, то это можно сделать проще.

Определяю значение поля curDate, которое встречается более одного раза

  
  SELECT tabMain.curDate  ;    
  FROM tabMain ;    
  GROUP BY tabMain.curDate ;  
  HAVING count(*) > 1

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Выбрать из дочерней таблицы записи с максимальной датой

Задача

Есть 2 таблицы (главная и подчиненная) связанные отношением один-ко-многим. Одно из полей подчиненной таблицы - это дата. Необходимо для каждой записи главной таблицы выбрать одну запись из подчиненной таблицы с максимальным значением даты. Т.е. не просто определить максимальную дату, а выбрать всю запись с этой максимальной датой

Решение

Исходные данные

  
 * Главная таблица  
  CREATE CURSOR tabMain (tabMainID I, NickName C(50))    
  INSERT INTO tabMain (tabMainID, NickName) VALUES (1, "Первая запись главной таблицы")    
  INSERT INTO tabMain (tabMainID, NickName) VALUES (2, "Вторая запись главной таблицы")    
  INSERT INTO tabMain (tabMainID, NickName) VALUES (3, "Третья запись главной таблицы")    
    
 * Подчиненная таблица  
 * Для первой записи главной таблицы есть дублирующее значение по максимальной дате  
 * Для второй записи главной таблицы вообще нет значений в подчиненной таблице  
  CREATE CURSOR tabChild (tabChildID I, tabMainID I, CurDate D, NickName C(50))    
  INSERT INTO tabChild (tabChildID, tabMainID, CurDate, NickName) ;  
  	VALUES (1, 1, DATE(2005,6,15), "Первая запись дочерней первой записи главной")  
  INSERT INTO tabChild (tabChildID, tabMainID, CurDate, NickName) ;  
  	VALUES (2, 1, DATE(2005,6,15), "Вторая запись дочерней первой записи главной")  
  INSERT INTO tabChild (tabChildID, tabMainID, CurDate, NickName) ;  
  	VALUES (3, 1, DATE(2005,6,10), "Третья запись дочерней первой записи главной")  
  INSERT INTO tabChild (tabChildID, tabMainID, CurDate, NickName) ;  
  	VALUES (4, 3, DATE(2005,6,13), "Первая запись дочерней третьей записи главной")  
  INSERT INTO tabChild (tabChildID, tabMainID, CurDate, NickName) ;  
  	VALUES (5, 3, DATE(2005,6,14), "Первая запись дочерней третьей записи главной")

У функции DATE() можно задавать параметры, начиная с версии Visual FoxPro 6. Для младших версий укажите значение даты другим способом.

Наиболее очевидным кажется решение через поиск максимального значения. Примерно так

  
  SELECT tabMain.*, tabChild.* ;  
  FROM tabMain ;  
  INNER JOIN tabChild ON tabMain.tabMainID=tabChild.tabMainID ;  
  WHERE tabChild.CurDate IN ;  
  	(SELECT MAX(CurDate) FROM tabChild WHERE tabMainID = tabMain.tabMainID)

Однако если в дочерней таблице есть записи с одинаковым значением даты и эти даты являются максимальными, то в результирующей выборке получим лишние записи. Попробуйте выполнить этот запрос для приведенных исходных данных и вы увидите в чем проблема.

Чтобы исключить отбор подобных "дублей" следует опираться на уникальный идентификатор записи. В данном случае это tabChild.tabChildID. С его помощью следует отделить одну запись от другой с одинаковой датой.

При этом, чтобы задействовать механизмы оптимизации следует отойти от "шаблона" поиска максимального значения. Точнее, следует вспомнить, что "максимальное" означает лишь тот факт, что нет значения больше, чем найденное. Это значит, что функцию MAX() можно заменить на сравнение "больше или меньше".

  
  SELECT tabMain.*, tab2.* ;  
  FROM tabMain ;  
  INNER JOIN tabChild tab2 ON tabMain.tabMainID=tab2.tabMainID ;  
  WHERE NOT EXISTS(SELECT 'x' FROM tabChild ;  
  		WHERE tab2.tabMainID = tabChild.tabMainID ;  
  			AND tab2.CurDate < tabChild.CurDate) ;  
  AND NOT EXISTS(SELECT 'x' FROM tabChild ;  
  		WHERE tab2.tabMainID = tabChild.tabMainID ;  
  			AND tab2.CurDate = tabChild.CurDate ;  
  			AND tab2.tabChildId < tabChild.tabChildId)

Разберем этот запрос подробнее.

Первое объединение по INNER JOIN просто связывает главную и подчиненную таблицу. Получим все записи подчиненной таблицы, соответствующие записям главной таблицы.

Теперь из этих записей надо оставить лишь те, дата в которых максимальная. Т.е. не существует записей (NOT EXISTS), которые также относились бы к той же записи главной таблицы и имели бы дату бОльшую, чем в найденной записи. Именно это и делает первый подзапрос.

А вот что делает второй подзапрос? Он предназначен именно для контроля той ситуации, когда в дочерней таблице могут быть записи с одинаковым значением даты. В данном случае, в случае наличия такой ситуации в выборку попадут только записи, имеющие бОльшее значение идентификатора записи. Но вы можете указать символ "больше", тогда будет отбираться запись имеющая меньшее значение идентификатора записи.

Обратите внимание, что здесь нельзя использовать для сравнения ключевых полей "не равно". Поскольку "не равно" будет справедливо для обоих записей с одинаковой датой.

К сожалению, в Visual FoxPro невозможно объединить эти два подзапроса в один. Впрочем, в таком виде запрос выглядит более наглядно. А если вы уверены, что в вашей таблице не может быть записей с одинаковым значением даты, то просто не включайте второй подзапрос.

В принципе, тот же самый алгоритм можно использовать, если надо найти не максимальную дату, а скажем, максимальную цену. Или максимальную сумму.

Если вы хотите получить в выборке все записи главной таблицы вне зависимости от того, есть ли для них хотя бы одна запись в подчиненной таблице, то достаточно заменить "INNER JOIN" на "LEFT JOIN" больше ничего не меняя в запросе.

===================================================================================

Есть еще одно, довольно экзотическое, решение. Оно заведомо не оптимизируемо, поэтому выполняется достаточно медленно.

Способ решения отличается для версии Visual FoxPro 9 и младших версий, поскольку в 9 версии значительно расширены возможности команды Select-SQL

  
 * Для версии младше Visual FoxPro 9  
    
  SELECT tabMain.*, tabChild.* ;  
  FROM tabMain ;  
  INNER JOIN tabChild ON tabMain.tabMainID=tabChild.tabMainID ;  
  WHERE tabChild.tabChildID IN ;  
  	(SELECT CTOBIN(RIGHT(MAX(DTOS(CurDate)+BINTOC(tabChildID)),4)) ;  
  			FROM tabChild GROUP BY tabMainID) ;  
  UNION ALL ;  
  SELECT tabMain.*, 0, 0, {}, '' ;  
  FROM tabMain ;  
  WHERE tabMain.tabMainID NOT IN (SELECT tabMainID FROM tabChild)  
    
 * Для Visual FoxPro 9  
    
  SELECT tabMain.*, tabChild.* ;  
  FROM tabMain ;  
  LEFT JOIN tabChild ON tabMain.tabMainID=tabChild.tabMainID ;  
  WHERE tabChild.tabChildID IS NULL ;  
  	OR tabChild.tabChildID IN ;  
  		(SELECT CTOBIN(RIGHT(MAX(DTOS(CurDate)+BINTOC(tabChildID)),4)) ;  
  			FROM tabChild GROUP BY tabMainID)

Основная идея заключается в том, что в подзапросе ищется не просто значение максимальной даты, а некоего "синтетического" ключа. Суммы строк даты и ключевого поля дочерней таблицы.

Для корректного определения максимального значения дата конвертируется в строку при помощи функции DTOS(). Т.е. это представления даты в виде "ГГГГММДД". Другими словами дата "15 июня 2005 года" будет выглядеть как "20050615".

В данном примере, ключевое поле дочерней таблицы имеет тип Integer. Для конвертации его в строку использована функция BINTOC() просто для того, чтобы получить как можно меньший размер. В данном случае получается строка длиной в 4 символа. А в случае стандартного преобразования через STR() пришлось бы выделить 10 символов. Отсечь ведущие пробелы в данном случае нельзя.

Найденное максимальное значение по такому выражению, по сути, означает, что в пределах одного значения поля tabMainID найдена запись с максимальным значением даты, а если существуют несколько записей с максимальным значением даты, то среди них отбирается запись с максимальным значением ключевого поля tabChilID.

После того, как будет найдено максимальное значение для такого "синтетического" ключа из него выделяются последние 4 символа и преобразуются к типу Integer. По сути, получаем значение кода записи дочерней таблицы для максимального значения даты.

Далее уже все просто. Используя конструкцию IN, отбираем нужные записи дочерней таблицы. Ну, а объединение нужно в том случае, если требуются еще данные из главной таблицы.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Почему возвращается только часть числа. Первые символы

Вопрос

При чтении числовых данных с SQL-сервера возвращается только часть числа. Первые символы или только целая часть без дробной части.

Причина

Причина в настройках конкретного соединения с SQL-сервера. Явно или не явно установлены региональные настройки. Обратите внимание, речь идет не о настройках собственно сервера, а о настройках соединения с сервером!

Проблема здесь в том, что числовые данные как правило, конвертируются в поля типа Numeric в среде FoxPro. А поля типа Numeric в FoxPro физически хранятся как символьные данные. Это значит, что в принципе, в такое поле можно записать любой символ. Вот ODBC и записал, например, символ запятой в соответствии с региональной настройкой.

Но при чтении данных для FoxPro символ запятой - это не есть символ, относящийся к числовым данным (символом-разделителем целой и дробной части непосредственно в таблице является точка). Следовательно, будут прочитаны как число только те символы, которые стоят ДО символа запятой.

Решение

Решение зависит от того, каким способом были установлены соответствующие настройки соединения.

MS SQL - сервер

Если Вы использовали для установки соединения предварительно настроенный DSN, то зайдите в настройки DSN-соединения и снимите "птичку" с настройки

"Use regional settings when outputting currency, numbers, dates, and times"

Если Вы использовали для установки соединения строку SQLStringConnect(), то убедитесь, что в ней нет опции Regional или же она имеет значение Regional=No

Oracle - сервер

Здесь придется явным образом менять настройку текущей сессии через прямую команду SQLExec() примерно так

SQLExec(m.nOraConnect,[ALTER SESSION SET NLS_NUMERIC_CHARACTERS='. '])

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как получить значение функции сервера

Вопрос

Как получить значение, возвращаемое моей функцией, написанной на SQL-сервере?

Ответ

Для этого используют специальную синтаксическую конструкцию

  
  LOCAL lnReturnValue  
  lnReturnValue = 0  
  SQLEXEC(m.lnHandle,"{?@lnReturnValue= Call MyFunction()}")   
  ?lnReturnValue

По аналогии с чтением значения параметров OUTPUT

Замечание

Данный прием не сработает для внутренних функций MS SQL. Т.е. таким образом невозможно будет получить значение, например, функции SCOPE_IDENTITY().

Для внутренних функций MS SQL следует использовать штатный механизм возвращения результатов запроса:

  
  SQLEXEC(m.lnHandle,"SELECT SCOPE_IDENTITY() as LastIdent","tabLastIdent")   
  ?tabLastIdent.LastIdent

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как получить значение выходного параметра процедуры сервера

Вопрос

На SQL-сервере создана процедура, имеющая выходной параметр. Т.е. параметр, имеющий признак OUTPUT. Как прочитать возвращаемое значение этого параметра.

Ответ

Синтаксис будет почти такой же, как и при передаче параметра в хранимую процедуру. Подробно это описано в статье "Как передать параметры в хранимую процедуру сервера"

Отличие заключается только в том, что используется не один символ вопросительного знака, а два символа: вопросительный знак и @.

  
  LOCAL lnPar1, lcPar2    
  lnPar1 = 123.456    
  lcPar2 = ""  && В эту переменную будет записано значение параметра OUTPUT  
  SQLExec(lnHandle,"{Call MyProc (?m.lnPar1, ?@m.lnPar2)}")

Разумеется, для конкретного SQL-сервера, кроме общего вызова через CALL, можно использовать вызов через соответствующие синтаксические конструкции конкретного сервера. Например, для MS SQL сервера можно использовать вызов через EXECUTE

  
  LOCAL lnPar1, lcPar2    
  lnPar1 = 123.456    
  lcPar2 = ""  && В эту переменную будет записано значение параметра OUTPUT  
  SQLExec(lnHandle,"Execute MyProc ?m.lnPar1, ?@m.lnPar2")

Замечание

Не используйте в качестве параметра переменные памяти с именем, состоящем из одной буквы. В этом случае такая конструкция может не сработать, поскольку в синтаксисе FoxPro за многими буквами закреплены имена рабочих областей. Например, буква "a" - это первая рабочая область.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как передать параметры в хранимую процедуру сервера

Вопрос

В пользовательской форме были сформированы некоторые значения. Как передать эти сформированные значения в качестве параметров в хранимую процедуру сервера?

Ответ

Для передачи значения как параметра в синтаксисе FoxPro используется вопросительный знак.

  
  LOCAL lnPar1, lcPar2  
  lnPar1 = 123.456  
  lcPar2 = "Новое значение"  
  SQLExec(lnHandle,"{Call MyProc (?m.lnPar1, ?m.lnPar2)}")

Все то, что следует за символом вопросительного знака до первого пробела или запятой - это параметр. Конвертация в тип, понятный SQL-серверу произойдет автоматически. Никаких дополнительных преобразований делать не надо.

В качестве параметра можно использовать не только переменные памяти, но и поля таблицы и объекты формы.

Обратите внимание на тот факт, что конвертация в тип, понятный SQL-серверу произойдет автоматически. Однако следует иметь в виду, что при определенных условиях подобной автоматизм может вызвать некоторые проблемы.

Например, для MS SQL сервера переменные памяти с дробной частью будут сконвертировны в тип REAL, что может привести к потере точности. Вместо точного значения 1.1 сервер интерпретирует это значение, как приближенное 1.0999999. В большинстве случаев - ничего страшного. Однако иногда это может иметь принципиальное значение.

Поэтому, если Вам необходимо передать данные "как есть", то придется самостоятельно формировать символьную строку.

  
  LOCAL lnPar1, lcPar2, lcStringSQL  
  lnPar1 = 123.456  
  lcPar2 = "Новое значение"  
  lcStringSQL = "{Call MyProc ("+TRANSFORM(m.lnPar1)+",'"+m.lcPar2+"')}"  
  SQLExec(lnHandle,m.lcStringSQL)

Замечание

Если Вы формируете символьную строку самостоятельно, то предварительно уточните как именно записываются константы разных типов в синтаксисе того или иного сервера.

Например, для MS SQL сервера символьная константа, по умолчанию, обрамляется одинарными кавычками. Двойными кавычками обрамляются имена объектов. Поэтому символьная константа обрамленная двойными кавычками может вызвать сообщение о синтаксической ошибке.

Константа типа Date или DateTime также может записываться разными способами. Хотя, универсальный формат, который понимают большинство серверов - это символьная строка вида 'ГГГГММДД'. Т.е. дата 6 января 2010 года должна быть записана как '20100106'

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как вызвать хранимую процедуру сервера

Вопрос

Как вызвать хранимую процедуру сервера?

Ответ

В FoxPro для этой цели можно использовать функцию SQLExec(). Стандартный синтаксис для вызова хранимой процедуры любого сервера является команда Call, обрамленная фигурными скобками. Примерно так:

SQLExec(m.lnHandle,"{Call MyProc (par1, par2)}")

Для MS SQL сервера можно использовать "локальный", т.е. пригодный только для сервера MS SQL способ вызова:

SQLExec(m.lnHandle,"EXECUTE MyProc par1, par2")

В данных примерах использовано следующее обозначение:

m.lnHandle - это число, являющееся номером ранее установленного соединения с сервером.
MyProc - имя запускаемой процедуры
par1, par2 - параметры, передаваемые в процедуру

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как подавить выдачу системного окна настройки соединения в случае ошибки

Вопрос

Я настриваю соединение программно через команду SQLConnect() или команду SQLStringConnect(). В случае ошибки создания соединения возникает системное окно для настройки реквизитов соединения. Как можно подавить выдачу этого окна, просто выдав пользователю сообщение об ошибке?

Ответ

Если Вы используете для создания соединения объект Connection базы данных, то откройте этот объект на редактирование и сделайте следующие настройки:

1. В разделе "Display ODBC login prompts" установите переключатель в положение "Never"
2. Убедитесь, что в разделе "Data Procesing" переключатель "Display Warnings" выключен

Если Вы настраиваете соединение исключительно программными средствами, то установить нужные значения этих настроек можно, используя функцию SQLSetProp(). Это настройки DispLogin и DispWarnings.

Однако, как видно из синтаксиса функции SQLSetProp(), она делает настройки для конкретного соединения. Первым параметром идет номер уже созданного соединения. Но ведь соединения еще нет. Его только собираются создать.

Чтобы преодолеть это противоречие, используют соединение с номером 0. Физически - это вообще не соединение. По сути, это будут настройки для любого нового соединения, поскольку номером 0 обозначают первое не занятое значение номера соединения. На уже созданные соединения эти настройки не распространяются.

Получается примерно такой код:

  
 * Сохранение текущих значений настроек  
  LOCAL llDispWarning, lnDispLogin  
  llDispWarning=SQLGetProp(0,'DispWarning')  
  lnDispLogin=SQLGetProp(0,'DispLogin')  
    
 * Установка этих настроек в значения, препятствующие выдаче системных сообщений  
  SQLSetProp(0,'DispWarning',.F.)  
  SQLSetProp(0,'DispLogin',3)  
    
 * Формируем строку соединения для MS SQL сервера  
  LOCAL lcStringConnect  
  lcStringConnect='DRIVER=SQL Server;'+;  
  		'SERVER=Имя_Сервера;'+;  
  		'UID=Логин_Пользователя;'+;  
  		'PWD=Пароль_Пользователя;'+;  
  		'DataBase=Имя_базы_данных'  
    
 * Собственно попытка создания соединения  
  lnNewConnection = SQLStringConnect(m.lcStringConnect)  
  IF m.lnNewConnection <= 0  
 	* Произошла ошибка в момент установки соединения. Выясняем причину  
  	LOCAL laError(1)  
  	=AERROR(laError)  
 	* Анализ массива laError для уточнения причины ошибки  
  ELSE  
 	* Соединение успешно установлено   
 	* и его номер записан в переменную lnNewConnection  
  ENDIF  
    
 * Восстановление исходных настроек  
  SQLSetProp(0,'DispWarning',m.llDispWarning)  
  SQLSetProp(0,'DispLogin',m.lnDispLogin)

В принципе, значение настройки DispWarning и так по умолчанию равно .F. Здесь это делается на всякий случай

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)

Как определить причину ошибки

Вопрос

Выполнение операции с SQL-сервером завершилось неудачей. Как определить факт того, что произошла ошибка, и какая именно ошибка произошла?

Ответ

Тот факт, что операция на сервере закончилась неудачей, определяется в зависимости от используемого способа обращения к серверу.

Если обращение идет через функции SQLExec(), то сама эта функция возвращает значение меньше нуля в случае ошибки.

Если обращение идет через RemoteView или Cursor Adapter, то операция сброса изменений на сервер осуществляется функцией TableUpdate(). В случае неудачи (ошибки) эта функция вернет .F.

Для определения причины возникновения ошибки предназначена функция AERROR(). Использовать можно следующим образом:

  
 * При работе через SQLExec()  
  IF SQLExec(...)<0  
  	LOCAL laError(1)  
  	=AERROR(laError)  
 	* Анализ массива laError для уточнения причины ошибки  
  ENDIF  
    
 * При работе через Remote View или Cursor Adapter  
  IF TableUpdate(.T.,.T.,"MyView")=.F.  
  	LOCAL laError(1)  
  	=AERROR(laError)  
 	* Анализ массива laError для уточнения причины ошибки  
  ENDIF

При работе с удаленными данными первый элемент полученного массива всегда будет иметь значение 1526 - ошибка ODBC-соединения.

Остальные элементы массива будут содержать информацию об ошибке самого сервера. Т.е., какая именно ошибка произошла на сервере.

Автор публикации

не в сети 26 лет

Владимир Максимов

Комментарии: 0Публикации: 65Регистрация: 02-09-2000

(далее…)